Kuinka nopeasti tulostaa kaikki Outlook-sähköpostikuvan liitteet vain yhdelle sivulle

Tulostimen musteen ja paperin säästämiseksi jotkut käyttäjät haluavat tulostaa kaikki sähköpostissa liitetyt kuvat vain yhdelle sivulle yhden kuvan sijasta sivua kohden. Nyt tämä artikkeli jakaa keinon sen toteuttamiseksi.

Kuten me kaikki tiedämme, kuvien tulostaminen tuhlaa tulostimen mustetta. Tällöin tulostimen musteen ja paperin säästämiseksi haluat mieluummin tulostaa useita kuvaliitteitä samalla sivulla sen sijaan, että tulostat kuvat erillisille sivuille. Vaikka Outlook ei tarjoa tällaista ominaisuutta, voit silti saavuttaa sen seuraavilla tavoilla.

Tulosta kaikki Outlook-sähköpostin liitetiedostot vain yhdelle sivulle

1. Aloita käynnistämällä Outlook-sovelluksesi.
2. Napauta sitten Outlook-ikkunassa Alt + F11-näppäinpainikkeita.
3. Seuraavaksi pääset "Microsoft Visual Basic for Applications" -ikkunaan, jossa sinun on ensin otettava käyttöön "Microsoft Word Object Library".
4. Sen jälkeen sinun on avattava moduuli, jota ei käytetä.
5. Kopioi ja liitä seuraava VBA-koodi tähän moduuliin.

Sub PrintAllImageAttachmentsOnOnePage()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objTempMail As Outlook.MailItem
    Dim objTempDocument As Word.Document
    Dim objWordApp As Word.Application
    Dim strImage As String
    Dim objImage As Word.InlineShape
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
       'Create a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       Set objTempDocument = objTempMail.GetInspector.WordEditor
       Set objWordApp = objTempDocument.Application
 
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.attachments
           'Get the Image attachments, instead of inserted Images
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          strImage = "E:\" & objAttachment.filename
                          objAttachment.SaveAsFile strImage
 
                          'Insert the images into the temp mail
                          Set objImage = objWordApp.Selection.InlineShapes.AddPicture(filename:=strImage, LinkToFile:=False, SaveWithDocument:=True)
                          objWordApp.Selection.TypeText Text:=" "
 
                          'shrink the images to insure that they are on one page
                          objImage.ScaleHeight = 20
                          objImage.ScaleWidth = 20
 
                          Kill strImage
             End Select
           End If
       Next
 
       objTempMail.PrintOut
       objTempMail.Close olDiscard
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

6. Myöhemmin voit palata sähköpostilistalle. Valitse tai avaa sähköposti, jonka kuvaliitteet haluat tulostaa.
7. Käynnistä sitten tämä makro. Paina vain nykyisessä makroikkunassa F5-näppäintä tai napsauta työkalupalkin Suorita-kuvaketta.
8. Lopuksi, kun makro on valmis, kaikki lähdesähköpostin kuvaliitteet tulostetaan yhdelle sivulle, kuten seuraava kuvakaappaus:

Käsittele vioittuneita Outlook-tiedostoja

Kun yhä enemmän tietoja on tallennettu Outlookiin, Outlook-tiedostosi on yhä haavoittuvampi. Se voi vaarantua useiden sisäisten ja ulkoisten tekijöiden vuoksi. Lisäksi on vaikea ennustaa Outlookin korruptiota. Joten mitä voit tehdä, on varmistaa välitön ja tehokas pelastus, kun kohtaat Outlook-vioittuneita. Esimerkiksi sinun on pidettävä erikoistunut PST-korjaus työkalu, kuten DataNumen Outlook Repair läheisyydessä. Se skannaa ja palauttaa vahingoittuneet tiedostot kuin tuulahdus.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien toipua Sql Server ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com