Kuinka viedä kaikki alikansiot ja kohteet sisältävä Outlook-kansio nopeasti Windows-kansioon

Toisinaan kannattaa ehkä viedä erä Outlook-kansio, jossa on kaikki alikansiot ja kohteet, Windows-kansioon. Tämä artikkeli opettaa sinulle sellaisen menetelmän, joka soveltaa Outlook VBA: ta.

Kun haluat viedä Outlook-kansion paikalliselle asemalle, jossa kaikki kohteet ovat samassa kansiorakenteessa, jos valitset tallentaa ja viedä manuaalisesti, se vie paljon aikaa. Miksi et siis käytä muita keinoja, kuten vientityökaluja tai VBA-koodeja? Täällä paljastamme sinulle tällaisen osan VBA-koodista. Se antaa sinun saavuttaa se kuin tuulta.

Vie kaikki Outlook-kansion alikansiot ja kohteet Windows-kansioihin

1. Käynnistä Outlook-ohjelmasi aivan aluksi.
2. Paina sitten Outlookin pääikkunassa Alt + F11-pikanäppäimiä.
3. Myöhemmin "Microsoft Visual Basic for Applications" -ikkuna avautuu.
4. Seuraavaksi sinun on avattava tyhjä moduuli ja kopioitava seuraavat VBA-koodit siihen.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Sen jälkeen sinun on varmistettava, että Outlook sallii makrot makroasetuksissa.
6. Lopulta voit kokeilla.

• Ensinnäkin, palaa uuteen makroikkunaan.
• Napsauta sitten "ExportFolderWithAllItems" -alirutiinia.
• Suorita tämä makro painamalla sitten F5-näppäintä.
• Sen jälkeen sinun on valittava tietty kansio.
• Lopuksi, kun saat viestin, jossa sanotaan "valmis", voit käyttää ennalta määritettyä paikallista kansiota. Löydät kaikki kohteet on tallennettu samaan kansiorakenteeseen.

Estä tietojen menetys Outlookin kaatumisista

Olet ehkä joskus törmännyt Outlookin kaatumisiin. Useimmiten Outlook toimii normaalisti uudelleenkäynnistyksen jälkeen. On kuitenkin myös mahdollista, että PST-tiedostomme vioittuu. Tällöin kannattaa yrittää parhaasi mukaan hakea PST-tiedot esimerkiksi kokeneella työkalulla, kuten DataNumen Outlook Repair. Se pystyy korjaa Outlook virheitä ja poimia tietoja vaarantuneesta PST-tiedostosta hikoilematta.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien SQL Server korjaus ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com