Kuinka viedä kaikkien PST-tiedostossa olevien kansioiden kokotiedot nopeasti Excel-tiedostoon

Jos haluat tarkistaa jokaisen PST-tiedoston kansion kokotiedot, voit käyttää tässä artikkelissa näkyvää menetelmää. Se vie nopeasti PST-tiedoston kaikkien kansioiden kokotiedot Excel-tiedostoon.

Kun PST-tiedostosi on liian suuri, kannattaa ehkä tarkistaa kunkin kansion koko. Se auttaa sinua selvittämään helposti suurimmat ja tekemään sopivan arkistoinnin koon perusteella. Yleensä voit tarkistaa kansion koon napsauttamalla kansiota hiiren kakkospainikkeella ja valitsemalla sitten Ominaisuudet. Uudessa ponnahdusikkunassa voit napsauttaa "Kansion koko" -painiketta. Jos olet kuitenkin luonut useita kansioita, kokotietojen tarkastaminen yksitellen manuaalisesti on huomattavan hankalaa. Joten, jos haluat erän hankkia PST-tiedoston kaikkien kansioiden kokotiedot, voit käyttää seuraavaa VBA-koodia. Se vie kaikki kansionimet ja kokotiedot Excel-tiedostoon yhdellä kertaa.

Vie kaikkien PST-tiedostossa olevien kansioiden kokotiedot Excel-tiedostoon

1. Aloita käynnistämällä Outlook-sovelluksesi.
2. Siirry sitten Kehittäjä-välilehteen ja napsauta Visual Basic -painiketta tai paina "Alt + F11" -näppäimiä päästäksesi VBA-editoriin.
3. Avaa seuraavaksi Microsoft Visual Basic for Applications -ikkunassa moduuli, jota ei käytetä.
4. Kopioi ja liitä seuraavat VBA-koodit sitten tähän moduuliin.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Sen jälkeen sinun tulisi asettaa Outlookin makrotason suojaustaso matalaksi.
6. Lopulta voit kokeilla.

• Paina F5-näppäintä nykyisessä makroikkunassa.
• Sitten sinua pyydetään valitsemaan PST-tiedosto, kuten seuraava kuva:
• Lähdetiedoston valitsemisen jälkeen Outlook alkaa viedä kokotiedot Exceliin.
• Kun makro on valmis, saat viestin, kuten alla oleva kuvakaappaus.
• Lopuksi voit löytää Excel-tiedoston ennalta määritetystä paikallisesta kansiosta. Excel-tiedosto näyttää tältä:

Käsittele usein PST-virheitä

Koska Outlook on altis virheille, olet ehkä koskaan kokenut monia ongelmia Outlookissasi. Turhauttavien PST-ongelmien selviämiseksi paremmin ja joustavammin on suositeltavaa pitää kokenut ja hyvämaineinen korjausohjelma lähellä, kuten DataNumen Outlook Repair. Se pystyy korjaa PST tuulen kaltaisia ​​ongelmia.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien SQL Server elpyminen ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com