Kuinka viedä Outlookin yhteysryhmän kaikkien jäsenten tiedot nopeasti Exceliin

Oletuksena näet vain yhteystietoryhmän jäsenten nimet ja sähköpostiosoitteet. Jos haluat saada jäsenten muut tiedot, voit käyttää tässä artikkelissa esiteltyä tapaa.

Kun kaksoisnapsautat yhteystietoryhmää avataksesi sen, näet sen ikkunassa vain ryhmän jäsenten nimet ja sähköpostiosoitteet. Et voi saada jäsenten muita tietoja, kuten yritystä, työnimikettä, puhelinnumeroa tai yrityksen osoitetta jne. Yleensä näiden tietojen saamiseksi sinun on löydettävä jäseniä vastaavat yhteystiedot Yhteystiedot-kansiostasi manuaalisesti. Se on liian hankalaa. Tässä näytämme sinulle osan VBA-koodista, joka voi viedä nämä tiedot nopeasti Excel-työkirjaan.

Vie yhteysryhmän kaikkien jäsenten tiedot Exceliin

1. Aloita käynnistämällä Outlook-sovelluksesi.
2. Sitten sinun tulee painaa "Alt + F11" pikanäppäimiä Outlookin pääikkunassa.
3. Seuraavaksi uudessa "Microsoft Visual Basic for Applications" -ikkunassa sinun on avattava käyttämätön moduuli tai asetettava suoraan uusi moduuli.
4. Kopioi ja liitä seuraava VBA-koodi tähän moduuliin.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Tämän jälkeen voit kätevästi tarkistaa lisäämällä uuden VBA-projektin pikatyökalupalkkiin tai nauhaan.
6. Aseta myöhemmin Outlook-makrosi suojaustaso alhaiseksi.
7. Viime kädessä voit kokeilla.

• Valitse ensin yhteysryhmä.
• Paina sitten pikatyökalupalkin tai nauhan makropainiketta.
• Makro käynnistyy välittömästi.
• Kun se on valmis, saat kehotteen "Complete!"
• Tämän jälkeen voit siirtyä ennalta määritettyyn kohdekansioon, josta löydät uuden Excel-tiedoston.
• Avaa se, niin näet ryhmän jäsenten yhteystiedot, kuten seuraavan kuvakaappauksen:

Älä panikoi Outlook-ongelmien edessä

Kukaan ei ole halukas hyväksymään Outlook-ongelmia, riippumatta ponnahdusikkunan virheilmoituksesta tai korruptoitunut Outlook tiedosto. Siksi käyttäjät joutuvat paniikkiin, kun he kohtaavat Outlook-ongelmia. Jos haluat pysyä rauhallisena siinä tapauksessa, sinulla pitäisi olla kaksi välttämätöntä asiaa. Yksi on nykyiset Outlook-tietojen varmuuskopiot. Toinen on tehokas Outlook-korjausohjelmisto, kuten DataNumen Outlook Repair.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien sql-palautus ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com