Kuinka asettaa eri muistutusaika Outlook-kokouksille eri väriluokissa

Jos luokittelet Outlook-kokouksia väriluokkien mukaan ja haluat asettaa erilaisen muistutusajan kokouksille eri väriluokissa, voit viitata tähän artikkeliin. Tässä opetamme sinua ymmärtämään sen Outlook VBA: lla.

Olet esimerkiksi jakamassa kokouksia kahteen ryhmään. Toinen on "Muualla"-väriluokassa, koska kokouspaikka on liian kaukana, ja toinen on "Paikan päällä"-väriluokassa, koska kokouspaikka on juuri täällä. Haluat nyt, että Outlook voi asettaa automaattisesti "muualla" pidettävän kokouksen muistutusajaksi 1 tunti ennen kokouksen alkua ja "paikalla pidettävän" kokouksen 15 minuuttia ennen kokouksen alkua. Tämän vaatimuksen täyttämiseksi jaamme jäljempänä nopean menetelmän.

Aseta automaattinen erilainen muistutus kokouksille eri väriluokissa

1. Aloita käynnistämällä Outlook-sovellus.
2. Paina sitten “Alt + F11” -näppäimiä päästäksesi VBA-editorin ikkunaan.
3. Kopioi ja liitä seuraavassa ikkunassa alla oleva VBA-koodi ThisOutlookSession-projektiin.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Myöhemmin sinun on napsautettava "Application_Startup"-aliohjelmaa ja painettava "F5"-näppäintä suorittaaksesi tämän makron.
5. Siitä lähtien, aina kun uusi kokous lisätään oletuskalenteriin tai muutat olemassa olevaa kokousta, Outlook tarkistaa kokouksen luokat automaattisesti ja asettaa erilaisen muistutusajan.

Poista Outlook-virheet

Outlookissa voi esiintyä erilaisia ​​ongelmia aika ajoin. Siksi on erittäin tärkeää, että käyttäjät oppivat selviytymään Outlookin ongelmista. Aluksi on parempi tehdä säännöllisesti Outlook-tietojen varmuuskopioita. Lisäksi, jos mahdollista, on suositeltavaa pitää yllä tehokasta varmuuskopiota. Outlookin korjaus työkalu lähellä, kuten DataNumen Outlook Repair. Se voi skannata PST-tiedostosi selvittääksesi Outlook-ongelmat ja ratkaista ne sitten helposti.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien sql-palautus ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com