Alkuperäisten lähettäjien ja vastaanottajien sähköpostiosoitteiden automaattinen poisto Outlook-sähköpostin edelleenlähetettäessä

Kun lähetät sähköpostin edelleen Outlookissa, alkuperäisen lähettäjän ja vastaanottajien sähköpostiosoitteet sisällytetään viestin tekstiin. Tässä vaiheessa turvallisuussyistä sinun on parempi poistaa nämä osoitteet. Tässä viestissä opit, miten Outlook voi tehdä tämän automaattisesti.

Monissa tapauksissa joudut edelleen välittämään joitain sähköposteja jollekin muulle. Oletusarvoisesti alkuperäisen sähköpostin otsikko näkyy edelleenlähetettävän sähköpostin rungossa. Ja otsikko sisältää alkuperäisen lähettäjän ja vastaanottajien sähköpostiosoitteet. Tässä vaiheessa sinun kannattaa poistaa nämä sähköpostiosoitteet turvallisuuden tai yksityisyyden vuoksi. On kuitenkin liian työlästä poistaa ne manuaalisesti. Siksi opastamme sinua tekemään Outlookin suorittamaan tämän tehtävän automaattisesti puolestasi.

Poista alkuperäisten lähettäjien ja vastaanottajien sähköpostiosoitteet automaattisesti, kun lähetät sähköpostia edelleen

1. Aloita käynnistämällä Outlook.
2. Paina sitten “Alt + F11” -näppäimiä päästäksesi VBA-editoriin.
3. Kopioi seuraavaksi seuraava VBA-koodi “ThisOutlookSession” -projektiin.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objRegExp As Object
    Dim strHTMLBody As String
 
    Forward.Display
    strHTMLBody = Forward.HTMLBody
 
    'Find email addresses in the body via Regular Expression
    Set objRegExp = CreateObject("vbscript.RegExp")
    With objRegExp
        .Pattern = "(?:[a-z0-9!#$%&'*+/=?^_`{|}~-]+(?:\.[a-z0-9!#$%&'*+/=?^_`{|}~-]+)*|""(?:[\x01-\x08\x0b\x0c\x0e-\x1f\x21\x23-\x5b\x5d-\x7f]|\\[\x01-\x09\x0b\x0c\x0e-\x7f])*"")@(?:(?:[a-z0-9](?:[a-z0-9-]*[a-z0-9])?\.)+[a-z0-9](?:[a-z0-9-]*[a-z0-9])?|\[(?:(?:25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\.){3}(?:25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?|[a-z0-9-]*[a-z0-9]:(?:[\x01-\x08\x0b\x0c\x0e-\x1f\x21-\x5a\x53-\x7f]|\\[\x01-\x09\x0b\x0c\x0e-\x7f])+)\])"
        .IgnoreCase = True
        .Global = True
    End With
 
    'Remove email addresses
    If objRegExp.Test(strHTMLBody) Then
       Set objFoundResults = objRegExp.Execute(strHTMLBody)
       For i = 1 To objFoundResults.Count
           Forward.HTMLBody = Replace(Forward.HTMLBody, objFoundResults.Item(i - 1).Value, "")
       Next
    End If
 
    'Remove useless characters
    Forward.HTMLBody = Replace(Forward.HTMLBody, "[mailto:]", "")
    Forward.HTMLBody = Replace(Forward.HTMLBody, "()", "")
End Sub

4. Käynnistä sen jälkeen Outlook-ohjelma uudelleen aktivoidaksesi tämän uuden makron.
5. Lopulta voit ottaa kuvan:

• Valitse tai avaa sähköposti.
• Napsauta sitten "Lähetä" -painiketta "Vastaa" -ryhmässä.
• Viimeisenä näytetään uusi edelleenlähetyssähköposti, josta alkuperäisen lähettäjän ja vastaanottajien sähköpostiosoitteet on poistettu.

Rauhoitu Outlook-korruptiotapauksissa

Kun sinulla on ongelmia Outlookissa, saatat joutua paniikkiin, pelätä Outlookin korruptio. Kuitenkin rehellisesti sanottuna kiire ja huoli voivat yleensä johtaa paljon muihin ongelmiin Outlookiin. Älä siis paniikkia, mutta ole rauhallinen asiaankuuluvissa tapauksissa. Lisäksi, jos olet säilyttänyt vankan PST-korjaustyökalun, kuten DataNumen Outlook Repair, voit käyttää sitä vain Outlook-ongelmien ratkaisemiseen.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien korjaa sql ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com