Kuinka lisätä syntymäpäivämuistutuksia käyttöoikeustietokantaan

Opi kuinka voit lisätä syntymäpäivämuistutuksia Access-tietokantaan. Ilmoita, jos asiakkaasi tai työntekijäsi syntymäpäivä on tulossa, jotta voit lähettää heille lämpimän tervehdyksen.

Syntymäpäivän tervehdysten lähettäminen voi olla hyvä tapa yhdistää ja vahvistaa suhdetta asiakkaaseen tai työntekijään. Jos käsittelet asiakkaan / työntekijän tietueita sisältävää Access-tietokantaa, voi olla hienoa saada ajoittain ilmoituksia asiakkaan tai työntekijän syntymäpäivästä. Tässä opetusohjelmassa opit, kuinka voit luoda toiminnon, joka ilmoittaa sinulle jonkun erityisestä päivästä heti, kun avaat tietokannan.

Lataa nyt

Jos haluat aloittaa ominaisuuden käytön mahdollisimman pian, voit:

Lataa näytetietokanta VBA-koodeilla nyt

Muussa tapauksessa voit lukea sisällön alla olevasta sisällöstä.

Edellytys

Tässä opetusohjelmassa oletetaan, että tietokannassasi on taulukko, joka sisältää nämä 3 kenttää: etunimi, sukunimi ja syntymäpäivä.

Vaiheet syntymäpäivämuistutusten lisäämiseksi Access-tietokantaan

1. Luo uusi taulukko ja nimeä se SyntymäpäiväJuhlajat. Tämä toimii syntymäpäiväjuhlien luettelona. Lisää 3 kenttää alla olevan kuvan mukaisesti. Ensisijaista avainta ei tarvita.
2. Luo lomake syntymäpäiväjuhlille. Tämä lomake tulee esiin, kun tietokanta avataan, jos tulevia syntymäpäiviä on.

• Valitse siirtymisruudussa BirthdayCelebrants-taulukko.
• Valitse Luo> Lomake.
• Sinulle luodaan automaattisesti yksi lomake.

Koska aiomme näyttää luettelon syntymäpäiväjuhlista, suosittelen, että vaihdat lomakkeen Oletusnäkymäksi joko Taulukko tai Jatkuvat lomakkeet. Tällä tavalla voit saada nopean yleiskuvan luettelosta.

• Valitse muotoilunäkymässä muoto.
• Avaa ominaisuusarkki (ALT + F11)
• Valitse Muotoile> Oletusnäkymä.
• Valitse haluamasi näkymä - joko tietolomake tai jatkuvat lomakkeet.

Jos olet valinnut Jatkuvat lomakkeet, muokkaa ulkoasua vastaamaan mieltymyksiäsi. Näin minuni näyttävät:

Olen muokannut Syntymäpäivä-tekstiruudun muotoa siten, että arvot näytetään Pitkä päivämäärä -muodossa. Tein myös seuraavat päivitykset lomakkeen ominaisuuksiin:

• Salli lisäykset: Ei
• Salli poistot: Ei
• Salli muokkaukset: Ei

Kun olet valmis, sulje lomake ja tallenna se nimellä frm_BirthdayCelebrants.

3. Lisää syntymäpäivämuistutuksen koodi.
   • Lisää uusi moduuli.
   • Tämä avaa VBA-editorin.
   • Lisää seuraava koodi ja muokkaa sitä tarpeidesi mukaan.

Public Function RunBirthdayReminders()
  Dim qry As String, fld_fName As String, fld_lName As String, fld_birthday As String, tbl As String
  Dim db As DAO.Database, rst As DAO.Recordset
 
  'TO DO: Update the ff. variables with the actual name of your table and fields
 
  tbl = "Members" 'table containing your client/employee reocrds
  fld_fName = "FirstName" 'first name field
  fld_lName = "LastName" 'last name field
  fld_birthday = "Birthday" 'birthday field
 
  Set db = CurrentDb
 
  'delete current record(s) from BirthdayCelebrants table
  DoCmd.SetWarnings False
  DoCmd.RunSQL ("DELETE FROM BirthdayCelebrants")
  DoCmd.SetWarnings True
 
  'insert new record(s) in BirthdayCelebrants table using a query that gets list of people celebrating their birthday today.
  qry = "INSERT INTO BirthdayCelebrants " & _
    "SELECT " & fld_fName & ", " & fld_lName & ", " & fld_birthday & " FROM " & tbl & " WHERE " & _
      "Month(" & fld_birthday & ")=Month(Date()) AND Day(" & fld_birthday & ")=Day(Date())"
 
  DoCmd.SetWarnings False
  DoCmd.RunSQL (qry)
  DoCmd.SetWarnings True
 
  Set rst = db.OpenRecordset("SELECT * FROM BirthdayCelebrants")
  If Not rst.EOF Then
    DoCmd.OpenForm ("frm_BirthdayCelebrants")
  End If
 
  Set db = Nothing
  Set rst = Nothing
End Function

Huomaa, että yllä oleva koodi käyttää kyselyä, joka saa luettelon syntymäpäiväjuhlista kuluvalle päivälle. Jos haluat saada luettelon ihmisistä, joiden syntymäpäivä on kuluvana kuukautena, käytä sen sijaan seuraavaa kyselyä.

'insert new record(s) in BirthdayCelebrants table using a query that gets list of people whose birthday is coming up for this month.
qry = "INSERT INTO BirthdayCelebrants " & _
  "SELECT " & fld_fName & ", " & fld_lName & ", " & fld_birthday & " FROM " & tbl & " WHERE " & _
    "Month(" & fld_birthday & ")=Month(Date()) AND Day(" & fld_birthday & ")>=Day(Date())" & _
      " ORDER BY Day(" & fld_birthday & ") ASC"

4. Lopuksi aiomme luoda AutoExec-makron. Tämä suorittaa koodin avattaessa tietokannan.
   • Valitse Luo> Makro.
   • valita RunCode avattavasta luettelosta.
   • Kirjoita Toiminnon nimi -kohtaan RunBirthdayReminders ().
   • Tallenna makro nimellä AutoExec ja napsauta OK.

5. Testaa nyt syntymäpäivämuistutuksesi.

Sulje tietokanta ja avaa se uudelleen. Jos syntymäpäiviä on tulossa, syntymäpäivämuistutuslomakkeen pitäisi ilmestyä. Jos ei, tietokanta toimii normaalisti.

Pika muistutus

Nyt nopea muistutus. Jos et voi avata tietokantaa jonain päivänä, älä paniikkia. Tee tarvittavat toimenpiteet sen palauttamiseksi. Jos et vieläkään pysty, kokeile kolmannen osapuolen ohjelmistoa korjaa pääsy. Toivoa on vielä.

Tekijän esittely:

Jayme Stack on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien sql-palautus ja Excel-palautusohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com