Cómo exportar por lotes las fotos e información de varios contactos con Outlook VBA

Si desea extraer las fotos de los contactos y su información principal a una carpeta en su disco local en lotes, debe usar Outlook VBA. Este artículo te enseñará cómo lograrlo en detalle.

Outlook le permite exportar la información de contacto a través de la función "Importar y exportar". Puede ir a "Archivo" > "Imprimir" > "Importar" > "Exportar a un archivo".

Sin embargo, esta función no le permite exportar las fotos de los contactos. Por lo tanto, si desea extraer tanto la información de contacto como las fotos, debe recurrir a Outlook VBA. Los siguientes son los códigos VBA y los pasos que pueden guardar las fotos de contacto en una carpeta local específica y extraer la información de contacto en un archivo de texto.

Exportación por lotes de fotos e información de múltiples contactos

1. En primer lugar, inicie Outlook y presione los botones de tecla "Alt + F11".
2. Luego obtendrá acceso al editor de VBA. Ahora debe abrir un módulo que no esté en uso o crear un nuevo módulo mediante "Insertar" > "Módulo".
3. Posteriormente, copie y pegue los siguientes códigos VBA en el nuevo módulo.

Sub BatchExportContactPhotosandInformation()
    Dim objContacts As Outlook.Items
    Dim objContact As ContactItem
    Dim strContactInfo As String
    Dim objFileSystem As Object
    Dim objTextfile As Object
    Dim objAttachments As Attachments
    Dim objAttachment As Attachment
    Dim strName As String
 
    'Specify the contacts in the default contact folder
    Set objContacts = Outlook.Application.Session.GetDefaultFolder(olFolderContacts).Items
 
    For Each objContact In objContacts
        If TypeOf objContact Is ContactItem Then
           'Get the contact's primary informtaion
           strContactInfo = "Name: " & objContact.FullName & vbCrLf & "Email: " & objContact.Email1Address & vbCrLf & "Company: " & objContact.Companies & vbCrLf & "Job Title: " & objContact.JobTitle & vbCrLf & "Business Address: " & objContact.BusinessAddress & vbCrLf & "Business Phone: " & objContact.BusinessTelephoneNumber
           'Create a Text file
           Set objFileSystem = CreateObject("Scripting.FileSystemObject")
           'You can change the folder path as per your needs
           Set objTextfile = objFileSystem.CreateTextFile("C:\Outlook Contacts\" & objContact.FullName & ".txt", True)
           objTextfile.WriteLine (strContactInfo)
 
           'Save the contact photos
           If objContact.Attachments.Count > 0 Then
              Set objAttachments = objContact.Attachments
              For Each objAttachment In objAttachments
                  If InStr(LCase(objAttachment.filename), "contactpicture.jpg") > 0 Then
                     strName = objContact.FullName & ".jpg"
                     objAttachment.SaveAsFile ("C:\Outlook Contacts\" & strName)
                  End If
              Next
           End If
       End If
    Next
End Sub

Nota: Los códigos anteriores exportarán las fotos y la información de los contactos en su carpeta de contactos predeterminada. Puede cambiar los contactos especificados.

• Si desea exportar las fotos y la información de los contactos en la carpeta abierta actualmente, debe reemplazar "Establecer objContacts = ….." con:

Set objContacts = Outlook.Application.ActiveExplorer.CurrentFolder.Items

• Si solo espera exportar las fotos y la información de los contactos seleccionados, puede usar las siguientes líneas:

Dim objSelection as Selection
Set objSelection = Outlook.Application.ActiveExplorer.Selection
For each objContact in objSelection

4. Después de eso, puede cerrar el editor de VBA y proceder a agregar el nuevo proyecto a la barra de herramientas de acceso rápido como de costumbre.
5. Finalmente, puede hacer clic en el botón macro en la barra de herramientas de acceso rápido. De inmediato, las fotos y la información de los contactos se exportarán a la carpeta especificada en el disco local.

Puede abrir un archivo de texto, en el que se enumerará la información principal, como la siguiente captura de pantalla:

Manejar la corrupción inesperada de Outlook

Es un hecho incuestionable que Outlook es vulnerable. Por lo tanto, si sufre corrupción de Outlook, lo primero que debe hacer es calmarse. Luego puede continuar reparando el Correo electrónico corrupto de Outlook PST. Puede usar la herramienta de reparación de la bandeja de entrada para intentarlo. Si falla, entonces no tiene más remedio que emplear una herramienta mucho más poderosa, como DataNumen Outlook Repair.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo reparar la base de datos SQL mdf dañada y productos de software de reparación de Outlook. Para más información visite www.datanumen.com