2 formas rápidas de exportar la lista de todos los correos electrónicos de Outlook marcados a Excel

Si desea exportar la lista de todos los correos electrónicos marcados desde su buzón de correo de Outlook a Excel, puede usar cualquiera de los 2 métodos compartidos en este artículo.

Por ejemplo, para tratar todos los correos electrónicos marcados de manera más oportuna o compartirlos con otra persona, puede esperar exportarlos a una hoja de cálculo de Excel. Aquí presentaremos 2 enfoques para realizarlo. El primero usa la función estándar "Importar y Exportar" después de encontrar correos electrónicos marcados. Para ser honesto, es un poco tedioso. Así, en este último te enseñaremos una forma más conveniente de aplicar VBA.

Método 1: exportar todos los correos electrónicos marcados encontrados manualmente

1. En primer lugar, haga clic en el cuadro de búsqueda que se encuentra sobre la lista de correo.
2. Luego, haga clic en "Todos los elementos de correo" en el grupo "Alcance" en la pestaña "Buscar".
3. A continuación, haga clic en el botón "Marcado" en el grupo "Definir".
4. Después de todos los correos electrónicos marcados que se muestran en la lista, seleccione un correo y presione "Ctrl + A" para seleccionarlos todos.
5. Luego, presione los atajos de teclas “Ctrl + Shift + V”.
6. En el nuevo cuadro de diálogo, cree una nueva carpeta en el archivo de Outlook.
7. Más tarde, seleccione la nueva carpeta creada y haga clic en "Aceptar", que moverá todos los correos electrónicos marcados encontrados a la nueva carpeta.
8. Luego, haga clic en "Archivo"> ​​"Abrir"> "Importar",
9. En el cuadro de diálogo emergente, elija "Exportar a un archivo"> ​​"Siguiente"> "Microsoft Excel 97-2003"> "Siguiente".
10. En la nueva pantalla, seleccione la carpeta correcta y presione "Siguiente".
11. Posteriormente, siga los asistentes para completar "Exportar".
12. Obtendrá un nuevo archivo de Excel, que se muestra en la siguiente captura de pantalla.

Método 2: exportar la lista de todos los correos electrónicos marcados a través de VBA

1. En Outlook, presione "Alt + F11" para activar el editor de VBA.
2. Luego, habilite "Objeto de MS Excel" de acuerdo con "Cómo agregar una biblioteca de objetosrary Referencia en VBA".
3. A continuación, copie el código VBA a continuación en un módulo.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Por último, coloque el cursor en la subrutina "ExportAllFlaggedEmailsToExcel" y presione el botón "F5".
5. Luego, seleccione un archivo de Outlook en el nuevo cuadro de diálogo.
6. Cuando reciba el mensaje "Completado", también obtendrá un nuevo archivo de Excel, como la imagen de abajo.

Proteja su Outlook de la corrupción

Outlook es propenso a errores y corrupción, por lo que es una tarea muy ardua para nosotros proteger nuestros datos de Outlook. Sin duda, la most Una forma eficaz y práctica es realizar copias de seguridad de datos periódicas para Outlook. Además, también es necesario que dispongamos de una herramienta de reparación de Outlook potente y fiable, como DataNumen Outlook Repair. Será útil si herramienta de reparación de la bandeja de entrada no tiene ningún efecto.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo reparar SQL Server y productos de software de reparación de Outlook. Para más información visite www.datanumen.com