2 formas rápidas de buscar o eliminar frases que contienen texto específico en su palabra

En este artículo, le ofreceremos 2 formas rápidas de buscar o eliminar oraciones que contienen texto específico en su Word.

Todos saben que podemos usar la función "Buscar y reemplazar" en Word para encontrar fácilmente todas las apariciones de palabras específicas. Entonces no tendremos ningún problema en resaltarlos, reemplazarlos o eliminarlos. Como ves, el tarobtener es una palabra o una frase. Hoy, sin embargo, nos complace contarle la forma macro de buscar o eliminar oraciones que contienen cierto texto.

Método 1: buscar o eliminar frases que contengan texto específico

1. Para empezar, presione "Alt + F11" para activar el editor de VBA en Word.
2. A continuación, cree un nuevo módulo haciendo clic en "Normal".
3. Luego haga clic en "Insertar" y elija "Módulo" para obtener uno nuevo.
4. Y abra el módulo con doble clic.
5. Ahora pega los siguientes códigos:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. A continuación, haga clic en "Ejecutar".
7. Habrá un cuadro de entrada que le pedirá que ingrese texto. Simplemente escriba el texto común que contienen todas las oraciones. Haga clic en Aceptar".
8. Luego verá una oración que contiene el texto seleccionado con un cuadro de mensaje que aparece. Haga clic en "Sí" para eliminar la oración y "No" para mantenerla.
9. Después de la confirmación, se selecciona la siguiente oración con el texto designado. Y también está el cuadro de confirmación. Es decir, la macro le lleva a recorrer todo el documento, encontrando tarobtener frases y pedir su confirmación cada vez.

Método 2: buscar o eliminar frases que contengan cualquier texto en una lista

Con la macro del método 1, solo puede buscar una palabra o frase a la vez. Ciertamente, puede ejecutar la macro repetidamente para buscar múltiples instancias de palabras o frases. Para satisfacer la necesidad de búsqueda múltiple, le proporcionaremos otra macro.

1. Primero pon todo tarobtener textos en un nuevo documento. Asegúrese de que cada fragmento de texto ocupe un párrafo sin espacios al final. Cierre y guarde el documento.
2. A continuación, instale y ejecute una macro con los pasos exactos del método 1.
3. Luego reemplace la macro con esta:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Ahora se abrirá la ventana "Examinar". Elija el documento que acaba de guardar y haga clic en "Abrir".
5. El siguiente procedimiento es el mismo que el del método 1.

Enfoque para lidiar con documentos corruptos

La pérdida de datos valiosos es absolutamente devastadora. Incluso puede dejar su negocio en juego. Para evitar tal frustración, necesita conseguir un Corrección de palabras herramienta lo antes posible. Esta herramienta le ayudará a ganar la batalla contra la corrupción de documentos.

Introducción del autor:

Vera Chen es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo arreglar Excel y pdf reparar productos de software. Para más información visite www.datanumen.com