So fügen Sie die zuletzt geänderte Datei in einem Windows-Ordner schnell an Ihre Outlook-E-Mail an

Manchmal möchten Sie möglicherweise die zuletzt geänderte Datei in einem bestimmten Windows-Ordner schnell finden und an eine Outlook-E-Mail anhängen. In diesem Fall können Sie die in diesem Artikel vorgestellte Methode verwenden.

Einige Benutzer möchten, dass Outlook die zuletzt geänderte Datei in einem Windows-Ordner schnell herausfindet und an eine E-Mail anhängt, z. B. das most kürzlich erstellte, geänderte oder gespeicherte Datei. Outlook bietet jedoch keine so direkte und native Funktion. Daher werden wir im Folgenden einen Teil des VBA-Codes verfügbar machen, der ihn problemlos realisieren kann.

Hängen Sie die zuletzt geänderte Datei in einem Windows-Ordner an E-Mail an

1. Gleich zu Beginn sollten Sie Ihre Outlook-Anwendung starten.
2. Nachdem Sie das Outlook-Hauptfenster aufgerufen haben, können Sie die Tasten „Alt + F11“ drücken.
3. Als Nächstes greifen Sie erfolgreich auf das Outlook VBA-Editorfenster zu.
4. Anschließend sollten Sie ein Modul finden und öffnen, das nicht verwendet wird.
5. Kopieren Sie anschließend den folgenden VBA-Code und fügen Sie ihn in dieses Modulfenster ein.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Danach können Sie das aktuelle VBA-Editorfenster verlassen und das neue Makro zur Symbolleiste für den Schnellzugriff oder zum Menüband des Nachrichtenfensters hinzufügen.
7. Später müssen Sie die Sicherheitsstufe Ihres Outlook-Makros auf niedrig ändern.
8. Schließlich können Sie es versuchen.

• Erstellen und erstellen Sie zunächst wie gewohnt eine neue Outlook-E-Mail.
• Klicken Sie dann auf die Makro-Schaltfläche in der Symbolleiste für den Schnellzugriff (siehe Abbildung unten):
• Als nächstes müssen Sie einen Windows-Quellordner auswählen und auf "OK" klicken.
• Wenn sich eine solche Datei im ausgewählten Windows-Ordner befindet, wird eine Eingabeaufforderung wie der folgende Screenshot angezeigt:
• Wenn Sie auf "Ja" klicken, wird diese Datei sofort angehängt.

Lösen Sie Outlook-Probleme so schnell wie möglich

Wenn Sie auf Outlook-Probleme stoßen, wird empfohlen, diese so schnell wie möglich zu beheben. In dieser Situation sollten Sie einen robusten vorbereiten Outlook beheben Werkzeug im Voraus, wie z DataNumen Outlook Repair. Es ist in der Lage, PST-Fehler zu beheben und Ihre Outlook-Daten effektiv zu retten.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich beschädigtes mdf und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX