6 Möglichkeiten, die ursprünglichen E-Mail-Anhänge beim Antworten in Outlook beizubehalten

Viele Benutzer hoffen, ihr Outlook so konfigurieren zu können, dass beim Beantworten einer E-Mail die ursprünglichen E-Mail-Anhänge beibehalten werden. In diesem Artikel werden 5 Problemumgehungen sowie eine intelligente Methode vorgestellt, bei der VBA verwendet wird, um sie automatisch zu realisieren.

Ich habe eine große Anzahl von Benutzern gehört, die sich darüber beschwert haben, dass Outlook keine native Funktion hat, um beim Beantworten einer E-Mail die ursprünglichen Anhänge beizubehalten. Daher werden wir Ihnen hier 6 Methoden vorstellen, von denen eine sehr nützlich ist, da VBA verwendet wird, um Outlook dazu zu bringen, die ursprünglichen Anhänge automatisch an die Beantwortung von E-Mails anzuhängen. Lesen Sie jetzt weiter, um sie im Detail zu erhalten.

1. Antworten Sie mit der beigefügten Original-E-Mail

Outlook bietet zwar keine Funktion zum Beibehalten der ursprünglichen E-Mail-Anhänge beim Beantworten einer E-Mail, ermöglicht es den Benutzern jedoch, die ursprünglichen E-Mail-Anhänge beizubehalten. Daher ist es eine optionale Problemumgehung für Sie. Sie können zu "Datei"> "Optionen"> "Mail"> "Antworten und Weiterleitungen" gehen, um die Antworteinstellungen zu ändern. Für weitere Informationen wird empfohlen, dass Sie sich auf meinen vorherigen Artikel beziehen - „5 Schritte zum Antworten mit Originalanhängen in Outlook”. Wenn Sie jedoch weiterhin nur Originalanhänge behalten möchten, lernen Sie die anderen Mittel kennen.

2. Ziehen Sie Anhänge manuell per Drag & Drop

1. Zu starDoppelklicken Sie mit auf eine solche Quell-E-Mail, um sie in einem eigenen Fenster zu öffnen.
2. Klicken Sie dann auf die Schaltfläche "Antworten", um die antwortende E-Mail aufzurufen.
3. Als nächstes sollten Sie beide Nachrichtenfenster verkleinern, bis Sie sie auf demselben Bildschirm sehen können.
4. Wählen Sie danach alle Anhänge in der ursprünglichen E-Mail aus.
5. Zuletzt ziehen Sie sie per Drag & Drop in die Zeile "Attached" in der antwortenden E-Mail.

3. Kopieren Sie Anhänge manuell und fügen Sie sie ein

1. Wählen Sie zunächst nach dem Öffnen der Quell-E-Mail alle Anhänge aus.
2. Klicken Sie dann auf der Registerkarte "Anhänge" auf die Schaltfläche "Kopieren".
3. Klicken Sie anschließend auf der Registerkarte "Nachricht" auf die Schaltfläche "Antworten", um eine antwortende E-Mail zu öffnen.
4. Klicken Sie in der antwortenden E-Mail in die Zeile "Angehängt" und drücken Sie die Taste "Strg + V", um die zuvor kopierten Anhänge einzufügen.

4. E-Mail weiterleiten und Empfänger ausfüllen

1. Wählen Sie zunächst eine solche E-Mail aus und klicken Sie dann in der Multifunktionsleiste auf die Schaltfläche "Weiterleiten".
2. Im neu eingeblendeten Nachrichtenfenster werden die ursprünglichen Anhänge beibehalten. Jetzt müssen Sie das Feld "An" an den Absender der ursprünglichen E-Mail ausfüllen.
3. Optional können Sie das Thema nach Ihren Wünschen wechseln.

5. Senden Sie diese E-Mail erneut und ändern Sie die Empfänger

1. Öffnen Sie zunächst die Quell-E-Mail.
2. Klicken Sie dann in der Gruppe "Verschieben" auf die Schaltfläche "Aktionen".
3. Wählen Sie anschließend "Diese Nachricht erneut senden" aus der Dropdown-Liste.
4. Möglicherweise erhalten Sie eine Benachrichtigung, in der darauf hingewiesen wird, dass Sie nicht der ursprüngliche Absender sind. Ignorieren Sie es einfach und klicken Sie auf "Ja".
5. In der nachfolgenden neuen E-Mail sollten Sie das Feld "An" an den Absender der ursprünglichen E-Mail ändern.
6. Denken Sie auch daran, das Senden per E-Mail-Konto in Ihr eigenes Konto zu ändern.

6. Fügen Sie über VBA automatisch Originalanhänge hinzu

Alle oben genannten Ansätze sind, um ehrlich zu sein, Problemumgehungen. Wenn Sie hoffen, dass Outlook beim Antworten automatisch die ursprünglichen Anhänge beibehalten kann, können Sie diese Methode verwenden.

1. Drücken Sie im Outlook-Hauptfenster die Tasten „Alt + F11“.
2. Kopieren Sie dann im Fenster "Microsoft Visual Basic für Applikationen" den folgenden VBA-Code in das Projekt "ThisOutlookSession".

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeName(objExplorer.Selection.Item(1)) = "MailItem" Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeName(Inspector.CurrentItem) = "MailItem" Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when clicking "Reply" button
Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

'Occurs when clicking "Reply All" button
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

Private Sub KeepOriginalAttachments(ByVal objOriginalMail As MailItem, objReply As Object)
    Dim strEnviro As String
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim objAttachment As Outlook.Attachment
 
    'Get the temp folder in Windows
    strEnviro = CStr(Environ("USERPROFILE"))
    strTempFolder = strEnviro & "\AppData\Local\Temp"
 
    For Each objAttachment In objOriginalMail.Attachments
        'Skip the embedded image attachments
        If IsEmbeddedAttachment(objAttachment) = False Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile strFilePath
 
           'Attach the temporarily saved attachments to the Reply
           objReply.Attachments.Add strFilePath
 
           'Delete the temporarily saved attachments
           Kill strFilePath
       End If
    Next
End Sub

'Function for checking if an attachment is embedded image attachment
Function IsEmbeddedAttachment(objCurrentAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurrentAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbeddedAttachment = True
    Else
       IsEmbeddedAttachment = False
    End If
End Function

3. Signieren Sie dieses Makro später und ändern Sie Ihre Outlook-Makroeinstellungen, um die signierten Makros zuzulassen.
4. Danach restart Ihre Outlook-Anwendung, um dieses VBA-Projekt zu aktivieren.
5. Von nun an jedes Mal, wenn Sie auf die Schaltfläche "Antworten" klicken. Die antwortende E-Mail wird sofort mit den Originalanhängen angezeigt.

Greifen Sie auf ein herausragendes Reparaturwerkzeug zurück

Outlook hat aufgrund seiner unzähligen Funktionen andere E-Mail-Clients übernommen. Aber es ist immer noch anfällig für Korruption. Daher sollten Sie mehr auf seine Gesundheit achten. Wenn kleine Probleme auftreten, können Sie im Allgemeinen einfach zum integrierten Fix-Dienstprogramm zurückkehren. Wenn Sie jedoch unter ernsthaften Problemen leiden, sollten Sie besser auf ein viel leistungsfähigeres Tool zurückgreifen, z DataNumen Outlook Repair. Es kann Outlook reparieren Datei in einem Augenblick.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich SQL Fix und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX