2 Schnelle Methoden zum Auffinden aller weitergeleiteten E-Mails in Ihrem Outlook

Wenn Sie schnell alle E-Mails finden möchten, die Sie in Ihrem Outlook an andere weitergeleitet haben, können Sie diesen Artikel lesen. Hier werden wir zwei effiziente Wege mit Ihnen teilen.

Wie wir alle wissen, enthalten die weitergeleiteten E-Mails einen blauen Rechtspfeil im Symbol. Es ist leicht an einer großen Anzahl von E-Mails zu erkennen. Manchmal möchten Sie möglicherweise alle in Ihrem Outlook weitergeleiteten Elemente überprüfen. In diesem Fall müssen Sie sie der Einfachheit halber herausfinden und am selben Ort sammeln. Outlook bietet keine direkten Kriterien für Benutzer zum Durchsuchen weitergeleiteter E-Mails. Sie können es jedoch immer noch leicht mit den folgenden 2 Mitteln erreichen.

Methode 1: Weitergeleitete E-Mails in einem Ordner suchen

1. Öffnen Sie zunächst einen E-Mail-Ordner, z. B. "Posteingang".
2. Wechseln Sie dann zur Registerkarte "Ansicht" und klicken Sie auf die Schaltfläche "Einstellungen anzeigen".
3. Klicken Sie anschließend im Popup-Dialogfeld auf die Schaltfläche "Filter".
4. Wechseln Sie anschließend im neuen Dialogfeld zur Registerkarte „SQL“.
5. Aktivieren Sie anschließend die Option „Diese Kriterien direkt bearbeiten. Alle anderen Registerkarten sind nicht verfügbar “unten.
6. Setzen Sie später den Cursor in das obige Feld und kopieren Sie die folgenden Kriterien hinein.

http://schemas.microsoft.com/mapi/proptag/0x10810003 = 104

7. Klicken Sie schließlich auf eine Reihe von "OK", um die Ansichtseinstellungen zu speichern.
8. Wenn Sie zum Ordner zurückkehren, werden Sie feststellen, dass sich dort nur weitergeleitete E-Mails befinden, wie in der folgenden Abbildung dargestellt.

Methode 2: Weitergeleitete E-Mails in allen Ordnern suchen

1. Für astart Starten Sie den Outlook VBA-Editor über „Alt + F11“.
2. Fügen Sie dann den folgenden VBA-Code in ein Modul ein.

Sub GetEmailForwardedStatus()
    Dim objPSTFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Process all folders in your default Outlook file
    Set objPSTFolders = Application.Session.GetDefaultFolder(olFolderInbox).Parent.Folders
 
    For Each objFolder In objPSTFolders
        If objFolder.DefaultItemType = olMailItem Then
           Call ProcessFolders(objFolder)
        End If
    Next
End Sub

Sub ProcessFolders(ByVal objFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objForwardedProperty As Outlook.UserProperty
    Dim strForwardedStatus As String
    Dim objSubFolder As Outlook.Folder
 
    'Get the forwarded status of all mails
    For i = objFolder.Items.Count To 1 Step -1
        If TypeOf objFolder.Items(i) Is MailItem Then
           Set objMail = objFolder.Items(i)
 
           Set objForwardedProperty = objMail.UserProperties.Find("Forwarded", True)
           If objForwardedProperty Is Nothing Then
              Set objForwardedProperty = objMail.UserProperties.Add("Forwarded", olText, True)
           End If
 
           strForwardedStatus = objMail.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x10810003")
           If strForwardedStatus = 104 Then
              objForwardedProperty.Value = "Yes"
           Else
              objForwardedProperty.Value = "No"
           End If
 
           objMail.Save
        End If
    Next
 
    'Process subfolders recursively
    If objFolder.Folders.Count > 0 Then
       For Each objSubFolder In objFolder.Folders
           If objSubFolder.DefaultItemType = olMailItem Then
              Call ProcessFolders(objSubFolder)
           End If
       Next
    End If
End Sub

3. Klicken Sie anschließend in die erste Unterroutine und drücken Sie die Taste „F5“.
4. Beenden Sie anschließend den VBA-Editor.
5. Klicken Sie anschließend in der E-Mail-Ordnerliste mit der rechten Maustaste auf "Suchordner" und wählen Sie "Neuer Suchordner".
6. Wählen Sie im Popup-Dialogfeld "Benutzerdefinierten Suchordner erstellen" und klicken Sie auf die Schaltfläche "Auswählen".
7. Geben Sie dann im Dialogfeld "Benutzerdefinierter Suchordner" "Weitergeleitete E-Mails" in das Feld "Name" ein und klicken Sie auf die Schaltfläche "Kriterien".
8. Wechseln Sie später im neuesten Dialogfeld zur Registerkarte "Erweitert" und fügen Sie den folgenden Filter hinzu.

• "Weitergeleitet"> "ist (genau)"> "Ja"

9. Klicken Sie abschließend auf mehrere "OK", um einen solchen benutzerdefinierten Suchordner zu erstellen.
10. Nach der erfolgreichen Erstellung wurden in diesem Suchordner alle weitergeleiteten E-Mails in der Standard-Outlook-Datendatei hier gesammelt (siehe Abbildung unten).

Entfliehen Sie dem Outlook-Datenverlust

Für jeden regulären Outlook-Benutzer ist ein Outlook-Datenverlust sicherlich nicht akzeptabel. Daher ist es wichtig, einige effektive Maßnahmen zu ergreifen, einschließlich regelmäßiger Datensicherungen für die PST-Dateien, des Erlernens der Verwendung des Inbox-Reparaturtools sowie der Vorbereitung eines zuverlässigen und leistungsstarken Tools PST beheben Werkzeug, wie DataNumen Outlook Repair. Selbst wenn die PST-Datei beschädigt ist, können Sie sie mit diesen Vorbereitungen mühelos wiederherstellen.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich beschädigtes SQL und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX