Sådan pakker du ud .Zip Vedhæftede filer direkte i Outlook via VBA

Når du modtager en vedhæftet fil i ".zip"filtypenavn, hvis du vil udpakke dem, skal du generelt gemme og udpakke dem på det lokale drev. Men mange håber at kunne udpakke dem direkte i Outlook. Denne artikel vil lære dig, hvordan du får det via VBA.

Du må nogensinde have modtaget de vedhæftede filer, der er i “.zip”Filtypenavn. For at få adgang til de interne filer i en zip filen, skal du først pakke den ud. I dette tilfælde skal du, som sædvanlig, først gemme den zip filen til det lokale drev, og højreklik derefter på den, og vælg "Udpak alt" i kontekstmenuen. I virkeligheden foretrækker mange brugere at udpakke filen direkte i Outlook. Outlook tilbyder dog ikke en sådan funktion. Heldigvis kan du følge nedenstående trin for at bruge VBA til at realisere det som en leg.

Pakk ud .Zip Vedhæftede filer direkte i Outlook

1. For det første skal du starte din Outlook-applikation.
2. Tryk derefter på "Alt + F11" -tastgenvej i Outlook-vinduet for at få adgang til VBA-editor.
3. Næste i vinduet “Microsoft Visual Basic for Applications” skal du åbne et modul, der ikke er i brug.
4. Kopier og indsæt derefter følgende VBA-koder i dette modul.

Public Sub UnzipFileInOutlook()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objShell As Object
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim strFileName As String
 
    Set objMail = Outlook.Application.ActiveInspector.CurrentItem
    Set objAttachments = objMail.attachments
 
    'Save & Unzip the zip file in local drive
    Set objShell = CreateObject("Shell.Application")
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "yyyy-mm-dd-hh-mm-ss")
    MkDir (strTempFolder)
 
    For Each objAttachment In objAttachments
        If Right(objAttachment.FileName, 3) = "zip" Then
           strFilePath = strTempFolder & "\" & objAttachment.FileName
           objAttachment.SaveAsFile (strFilePath)
           objShell.NameSpace((strTempFolder)).CopyHere objShell.NameSpace((strFilePath)).Items
        End If
    Next
 
    'Reattach the files extracted from the zip file
    strFileName = Dir(strTempFolder & "\")
 
    While Len(strFileName) > 0
          objMail.attachments.Add (strTempFolder & "\" & strFileName)
          strFileName = Dir
          objMail.Save
    Wend
 
    'Delete the attachments in “.zip” file extension
    Set objAttachments = objMail.attachments
    For Each objAttachment In objAttachments
        If Right(objAttachment.FileName, 3) = "zip" Then
           objAttachment.Delete
           objMail.Save
        End If
    Next
 
    'Delete the temp folder and files
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Derefter kan du tilføje det nye VBA-projekt til Quick Access Toolbar i meddelelsesvinduet som normalt.
6. Endelig kan du prøve.

• Åbn først en besked med zip fil i sit eget vindue.
• Klik derefter på "Handlinger"> "Rediger besked".
• Klik derefter på den nye makroknap i værktøjslinjen Hurtig adgang.
• Med det samme zip Filen vil blive udpakket, som på følgende skærmbillede:

Slip af med irriterende PST-problemer

Selvom PST-filen i nyt Unicode-format understøtter 20 GB filstørrelse, er det stadig klogt at holde filen så lille som muligt. Det er fordi, at en stor PST-fil er meget mere tilbøjelig til korruption. Når din PST-fil bliver kompromitteret, bliver du nødt til at gøre en indsats for at gendanne PST data. I dette scenario har du intet andet valg end at vende tilbage til et velprøvet og velrenommeret værktøj som DataNumen Outlook Repair.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder sql reparation og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com