Sådan finder du hurtigt afsnit med én sætning i dit Word-dokument

I dette indlæg vil vi vise dig den hurtige måde at finde alle afsnit på én sætning i dit Word-dokument via VBA.

Af og til kan nogle dokumenter have meget specifikke krav til deres formatering og strukturer. For eksempel har du muligvis ikke tilladelse til at have afsnit med kun en sætning. Disse afsnit er ikke svære at genkende, men det tager tid, især det er et langt dokument.

I dag tilbyder vi dig den hurtige måde at specificere alle afsnit med en sætning i dit dokument.

Find alle afsnit med én sætning i ét dokument

1. For det første tæller Word en periode som en sætning. Så hvis der er ord som "Mr." eller "fru.", Word betragter det som en sætning. For at udelukke en sådan distraktion skal du erstatte "Mr." med “Mr”. Og når du er færdig med at finde afsnit i en enkelt sætning, kan du ændre dem tilbage. For at erstatte ord kan du henvise til dette link: Sådan finder du og erstatter flere emner i dit Word-dokument
2. For det andet skal du trykke på “Alt + F11” for at udløse VBA-editor.
3. Klik derefter på “Normal” -projektet.
4. Klik på fanen "Indsæt" på menulinjen, og vælg "Modul" i rullemenuen.
5. Næste dobbeltklik på modulet for at åbne det.
6. Indsæt følgende koder på modulet:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Sidst men ikke mindst skal du klikke på "Kør" -knappen eller trykke på "F5".

Du vil modtage en sådan meddelelsesboks, der fortæller dig, at jobbet er udført.

Find alle afsnit med én sætning i flere dokumenter

1. Til at begynde med skal du placere alle måldokumenter i en mappe.
2. Installer og kør derefter bølgende makro:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. I vinduet "Gennemse" skal du vælge den mappe, hvor du opbevarer dokumenter, og klikke på "OK".

Makroen markerer derefter alle afsnit i en sætning og lader dokumenter være åbne. Hvis et dokument ikke indeholder et afsnit med en sætning, lukkes det. Derudover er der en meddelelsesboks, der angiver antallet af afsnit i en sætning i hvert dokument.

Håndter datatabshændelse

Brugerfejl og pludseligt strømafbrydelse kan resultere i, at Word dør. Mens et sammenklappet ord ikke kun kan påvirke det daglige arbejde, men også føre til doc skaderDette er på ingen måde den mest irriterende del af en datakatastrofe. Det er bedre at få et reparationsværktøj til at gendanne data med det samme.

Forfatter Introduktion:

Vera Chen er en datagendannelsesekspert i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder genvinde excel og pdf produkter til reparation af software. For mere information besøg www.datanumen.com