Sådan eksporterer du hurtigt oplysningerne om alle medlemmer i en Outlook-kontaktgruppe til Excel

Som standard kan du kun se medlemsnavne og e-mailadresser i en kontaktgruppe. Hvis du ønsker at få medlemmernes øvrige detaljer, kan du bruge den måde, der er introduceret i denne artikel.

Når du dobbeltklikker på en kontaktgruppe for at åbne den, i dens vindue, kan du kun se gruppemedlemmernes navne og e-mailadresser. Du er ikke i stand til at få medlemmers øvrige oplysninger, såsom virksomhed, stillingsbetegnelse, telefonnummer eller virksomhedsadresse osv. For at få disse oplysninger skal du generelt finde de kontakter, der svarer til medlemmerne i din Kontakter-mappe. Det er for besværligt. Her vil vi vise dig et stykke VBA-kode, som hurtigt kan eksportere disse detaljer til en Excel-projektmappe.

Eksporter oplysningerne om alle medlemmer i en kontaktgruppe til Excel

1. Til at begynde med skal du starte din Outlook-applikation.
2. Derefter skal du trykke på "Alt + F11" genvejstaster i hovedvinduet i Outlook.
3. Dernæst i det nye "Microsoft Visual Basic for Applications"-vindue skal du åbne et modul, der ikke er i brug, eller direkte indsætte et nyt modul.
4. Kopier og indsæt derefter følgende VBA-kode i dette modul.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Derefter kan du, for bekvem kontrol, tilføje det nye VBA-projekt til Quick Access Toolbar eller bånd.
6. Indstil senere dit Outlook-makrosikkerhedsniveau til lavt.
7. I sidste ende kan du prøve.

• Først skal du vælge en kontaktgruppe.
• Tryk derefter på makroknappen i værktøjslinjen Hurtig adgang eller båndet.
• Umiddelbart vil makroen køre.
• Når det er færdigt, får du en prompt med "Fuldfør!"
• Derefter kan du gå til den foruddefinerede lokale destinationsmappe, hvor du kan finde en ny Excel-fil.
• Åbn den, du vil se gruppemedlemmernes kontaktoplysninger som følgende skærmbillede:

Gå ikke i panik over Outlook-problemer

Ingen er villige til at acceptere nogen Outlook-problemer, uanset popup-fejlmeddelelse eller korrupt Outlook datafil. Derfor vil brugere have tendens til at få panik, når de støder på Outlook-problemer. Hvis du i så fald vil bevare roen, bør du have to fornødenheder i hånden. Den ene er aktuelle Outlook-datasikkerhedskopier. Den anden er potent Outlook fix software, som DataNumen Outlook Repair.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder sql opsving og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com