Sådan udelukker du hurtigt originale "CC"-modtagere, når du bruger "Svar alle" i Outlook

Når du bruger "Svar alle", vil den besvarende e-mail også indeholde "CC"-modtagere af den originale e-mail i "CC"-feltet. Men hvis du ønsker at udelukke denne type modtager, kan du bruge den metode, der er introduceret i denne artikel.

Til tider ønsker du at besvare en e-mail til den oprindelige afsender og "Til"-modtagere. I dette scenarie vil du helt sikkert overveje at bruge "Svar alle". Men på denne måde, hvis den originale mail også har "CC"-modtagere, vil "Svar alle"-e-mailen automatisk kopiere "CC"-modtagerne til "CC"-feltet. Hvis du ikke vil svare på dem, skal du fjerne dem manuelt, hvilket er lidt besværligt. Nu, i det følgende, vil vi lære dig, hvordan du lader Outlook auto udføre det efter dine behov.

Ekskluder hurtigt originale "CC"-modtagere, når du bruger "Svar alle"

1. Til at starte med, start Outlook.
2. Så få adgang til VBA editor ved at læse den forrige artikel - "Sådan køres VBA-kode i din Outlook".
3. Kopier derefter følgende VBA-kode til projektet "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when you click "Reply All"
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objRecipient As Outlook.Recipient
    Dim i As Long
 
    'Ask you if to exclude CC recipients
    If MsgBox("Do you want to exclude original CC recipients? " , vbQuestion + vbYesNo) = vbYes Then
       'If select Yes, remove CC recipients
       For i = Response.Recipients.Count To 1 Step -1
           If Response.Recipients(i).Type = olCC Then
              Response.Recipients.Remove (i)
           End If
       Next
    End If
End Sub

4. Genstart derefter din Outlook for at aktivere dette nye projekt.
5. Siden da, hver gang du trykker på knappen "Svar alle", vil du få en prompt, som vist på det følgende billede, der spørger, om du vil udelukke originale CC-modtagere.
6. Hvis du vælger "Ja", vil Outlook automatisk fjerne modtagerne i "CC"-feltet.

Hold dig godt forberedt på Outlook-skader

Som vi alle ved, kan ingen 100% garantere, at de er immune over for skader fra Outlook. Derfor er det vigtigt for alle almindelige Outlook-brugere at tage mange forholdsregler. Først og fremmest er en af ​​de mest afgørende at have en konsekvent og opdateret sikkerhedskopi af Outlook-data. Dernæst er det nødvendigt at lære, hvordan man bruger reparationsværktøjet til indbakken. Sidst men ikke mindst er det klogt og anbefales at have en erfaren Outlook-rettelse værktøj i nærheden, f.eks DataNumen Outlook Repair.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder gendanne mdf og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com