Sådan vises de tilsvarende persons aldre for alle fødselsdagsbegivenheder i listevisning af Outlook-kalenderen

Nogle brugere vil også gerne se den tilsvarende persons alder, når de ser en fødselsdagsbegivenhed i kalenderen. Derfor deler vi i denne artikel en metode til at få denne idé til at gå i opfyldelse med lethed.

Når du føjer fødselsdagsoplysningerne til en kontakt, opretter Outlook automatisk en fødselsdagshændelse i kalenderen. Under denne omstændighed, hver gang du ser fødselsdagsbegivenheder i kalenderen, vil du muligvis også få de tilsvarende personers aldre. Så her introducerer vi dig en måde at realisere det på.

Vis de tilsvarende personers aldre for alle fødselsdagsbegivenheder i listevisning

1. I begyndelsen skal du starte Outlook VBA-editor.
2. Kopier derefter følgende kode til et modul.

Sub ShowAgesOfBirthdayEventsListView()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Process All Calendar Folders in Your Outlook
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olAppointmentItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCalendar As Outlook.Folder)
    Dim i As Integer
    Dim objItem As Object
    Dim objBirthdayEvent As Outlook.AppointmentItem
    Dim dStart, dBirth As Date
    Dim nAge As Integer
    Dim objNewProperty As Outlook.UserProperty
    Dim objSubCalendar As Outlook.Folder

    For i = objCalendar.Items.Count To 1 Step -1
        Set objItem = objCalendar.Items.Item(i)
        'Add "Age" Property to Birthday Events
        If (objItem.MeetingStatus = olNonMeeting) And (objItem.IsRecurring = True) And (Right(objItem.Subject, 11) = "'s Birthday") Then
           Set objBirthdayEvent = objItem
           dStart = objBirthdayEvent.Start
 
           'Count Age
           dCurrentBirthday = DateSerial(Year(Now), Month(dStart), Day(dStart))
           nAge = DateDiff("yyyy", dStart, dCurrentBirthday)
 
           Set objNewProperty = objBirthdayEvent.UserProperties.Find("Age", True)
           If objNewProperty Is Nothing Then
              Set objNewProperty = objBirthdayEvent.UserProperties.Add("Age", olText, True)
           End If
 
           objNewProperty.value = nAge
           objBirthdayEvent.Save
        End If
    Next
 
    'Process All Sub-Calendar Folders Recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call ProcessFolders(objSubCalendar)
       Next
    End If
End Sub

3. Derefter skal du placere markøren i den første underrutine og trykke på "F5" for at køre denne makro.
4. Når makroen er færdig, skal du afslutte VBA-editoren og åbne en kalendermappe.
5. Gå derefter til fanen "Vis" og klik på "Skift visning"> "Liste".
6. Klik derefter på knappen "Vis indstillinger".
7. I pop op-dialogboksen skal du vælge “Kolonner”.
8. Vælg derefter "Brugerdefinerede felter i mappe" i listen over "Vælg tilgængelige felter fra" i den næste dialogboks under "Vis kolonner".
9. Senere skal du tone på "Alder" i feltet "Tilgængelige kolonner" og klikke på knappen "Tilføj ->".
10. Til sidst skal du klikke på en række “OK”, indtil du går tilbage til listen over kalenderelementer.
11. Nu på listen kan du se personernes alder for alle fødselsdagsbegivenheder, som vist i følgende figur.

Fix kompromitteret Outlook-fil

Du kan få panik, når du støder på korrupt Outlook fil, der indeholder mange af dine værdifulde e-mails og tidsplaner. På trods af at et sådant spørgsmål er ret desperat, skal du stadig falde til ro med det samme og overveje effektive foranstaltninger. Hvis du bliver bekymret, kan situationen blive værre og værre. Der er faktisk flere måder og hjælpeprogrammer, der kan reparere den beskadigede fil, såsom reparationsværktøj til indbakken og et mere robust og erfaren værktøj, som f.eks. DataNumen Outlook Repair.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder SQL Server fastsætte og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com