Sådan markeres weekendaftaler automatisk som private i Outlook

Outlook-løsninger September 29, 2025

Formost brugere, de aftaler, der er planlagt i weekenden, er normalt private. Derfor vil de have, at Outlook automatisk markerer og viser sådanne aftaler som private. I denne artikel vil vi gøre dette til virkelighed med lidt scripting.

For lettere at skelne mellem forretningsmæssige og private aftaler tillader Outlook brugere at markere aftaler som private. På denne måde finder du det ret praktisk og nemt at udskrive kalender uden private aftaler. I denne situation kan du muligvis ønske, at din Outlook automatisk genkender og markerer specifikke aftaler som privat. For eksempel er aftalerne i weekenden generelt private, så du vil lade Outlook automatisk markere dem som private. Herefter vil vi guide dig til at opnå det.

Marker weekendaftaler automatisk som private

  1. Start først Outlook VBA-editor i henhold til “Sådan køres VBA-kode i din Outlook".
  2. Derefter, i "Microsoft Visual Basic for Applications" vindue, sætte følgende kode i "ThisOutlookSession" projektet.
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olAppointment Then
       Set objAppointment = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objAppointment_Open(Cancel As Boolean)
    Call MarkWeedendAppointmentPrivate(objAppointment)
End Sub

Private Sub objAppointment_PropertyChange(ByVal Name As String)
    If Name = "Start" Or Name = "End" Then
       Call MarkWeedendAppointmentPrivate(objAppointment)
    End If
End Sub

Private Sub MarkWeedendAppointmentPrivate(ByVal objAppointment As Outlook.AppointmentItem)
    Dim dStartDate As Date
 
    dStartDate = Format(objAppointment.Start, "Short Date")
 
    'If the appointment start falls on weekend
    Select Case Weekday(dStartDate)
           Case 7, 1
                'Mark it private
                objAppointment.Sensitivity = olPrivate
    End Select
End Sub

VBA-kode - Marker automatisk aftaler om weekend som private

  1. Derefter restart Outlook for at aktivere makroen.
  2. Fra nu af, hver gang du opretter en ny aftale eller ændrer en eksisterende aftale til weekenden, markerer Outlook den automatisk som privat.Marker weekendaftaler automatisk som private

Løs irriterende Outlook-problemer

Det er muligt, at du har stødt på nogle problemer, når du beskæftiger dig med Outlook, såsom uventet applikationsfrysning, popup-fejlmeddelelser og så videre. Når du lider dem, ville du være bekymret. Vær rolig! Panik hjælper intet, men forværrer sagen. For det første kan du kontrollere, om du har adgang til PST-filen som normalt. I så fald skal du reparere PST-filen, som kan udføres via værktøj til reparation af indbakke eller et mere kraftfuldt eksternt værktøj som DataNumen Outlook Repair.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder mdf reparation og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com

Kommentarer er lukket.