2 metoder til at eksportere alle medlemmer af en Outlook-kontaktgruppe til Excel

Nogle gange vil du måske eksportere medlemmerne i en bestemt Outlook-kontaktgruppe. Så denne artikel vil dele dig 2 måder at udtrække gruppemedlemmerne til Excel.

Outlook tilbyder en indbygget funktion, som tillader dig at eksportere alle kontakter i en bestemt kontaktmappe. Det tillader dig dog ikke at eksportere kontaktgrupper, for ikke at nævne at udtrække medlemmerne i kontaktgrupperne. Derfor, hvis du gerne vil udtrække medlemmerne af en udvalgt kontaktgruppe, skal du gøre en ekstra indsats. Her er to tips, du kan henvise til.

Metode 1: Udpak gruppemedlemmerne via Gem som

1. Start Outlook i starten.
2. Find og vælg derefter den kontaktgruppe, hvis medlemmer du skal udtrække.
3. Derefter skal du gå til menuen "Filer" og klikke på "Gem som".
4. Efterfølgende, i pop op-vinduet "Gem som"-dialogboksen, vælg en destinationsmappe, der skal gemmes, og vælg "Kun tekst" fra rullelisten med "Gem som type".
5. Og klik derefter på "Gem".
6. Åbn derefter Excel og opret en ny excel-fil.
7. Senere skal du gå til "Filer" og klikke på knappen "Åbn".
8. I den efterfølgende "Åbn"-dialogboks skal du først få adgang til den mappe, hvor du lige har gemt kontaktgruppen.
9. Klik derefter på den anden boks i linjen "Filnavn", og vælg "Alle filer" fra rullelisten.
10. Derefter skal du slå tekstfilen til kontaktgruppen og trykke på "Åbn".
11. I popup-dialogboksen "Tekstimportguide" skal du sikre dig, at "Afgrænset" er valgt, og klik på knappen "Udfør".
12. Til sidst får du medlemmerne, som følgende skærmbillede:

Metode 2: Udpak gruppemedlemmerne via Outlook VBA

1. For det første skal du trykke på “Alt + F11” -tasten i Outlook.
2. Åbn derefter et nyt modul i VBA-editorvinduet.
3. Kopier derefter følgende VBA-koder ind i den.

Sub ExtractContactGroupMembersToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objMember As Outlook.recipient
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strPath As String
    Dim strFilename As String
 
    Select Case Application.ActiveWindow.Class
           Case olExplorer
                Set objContactGroup = Application.ActiveExplorer.Selection(1)
           Case olInspector
                Set objContactGroup = Application.ActiveInspector.CurrentItem
    End Select
 
    If TypeOf objContactGroup Is DistListItem Then
       'Create a new Excel workbook
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkBook = objExcelApp.Workbooks.Add
       Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
       'Set the two column headers
       objExcelWorkSheet.Cells(1, 1) = "Contact Name"
       objExcelWorkSheet.Cells(1, 2) = "Email Address"

       nRow = 2
 
       'Extract the contact group members' names and email addresses
       For i = 1 To objContactGroup.MemberCount
           Set objMember = objContactGroup.GetMember(i)
           objExcelWorkSheet.Cells(nRow, 1) = objMember.Name
           objExcelWorkSheet.Cells(nRow, 2) = objMember.Address
           nRow = nRow + 1
       Next
 
       'AutoFit the columns in the new Excel worksheet
       objExcelWorkSheet.Columns("A:B").AutoFit
 
       'Change the strPath to your actual case
       strPath = "C:\Contact Groups\"
       strFilename = strPath & objContactGroup.DLName & ".xlsx"
 
       'Save the Excel workbook
       objExcelWorkBook.Close True, strFilename
 
       'Notify you of the export complete
       MsgBox ("Export Complete!")
    End If
End Sub

4. Derefter kan du tilføje makroen til Quick Access Toolbar (QAT) som normalt.
5. Senere kan du vælge en kontaktgruppe og klikke på makroknappen i QAT.
6. Efter eksport vil du modtage en besked - "Eksport er fuldført!"
7. Til sidst kan du finde Excel-filen i mappen, som er forudbestemt i VBA-koder. Åbn det, du kan se gruppemedlemmerne, som billedet nedenfor:

Få dine tidligere PST-data tilbage

Da Outlook er modtagelig for at gå ned, kan dine PST-data blive ødelagt uden nogen varsler. Derfor bør du lave en regelmæssig backup af dine PST-filer. Du må også hellere forberede et potent værktøj, som f.eks DataNumen Outlook Repair, Hvilket kan reparere Outlook data til tiden.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder rette sql og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com