Sådan batches du svar på flere e-mails med samme indhold i din Outlook

Mange brugere beder om en løsning, der giver dem mulighed for batch-svar på flere valgte e-mails med samme indhold i Outlook. Selvom Outlook ikke leverer en sådan funktion, kan du stadig opnå det via et stykke VBA-kode.

Jeg har hørt et stort antal brugere, der klager over, at Outlook ikke har en funktion, der understøtter dem til at sende det samme svar til flere e-mails på én gang. Når de vælger flere e-mails, vil både "Svar" og "Svar alle" handlinger blive gråtonede - deaktiveres. Når vi ser på dette problem, vil vi dele en metode til at realisere denne funktion.

Batch Svar Flere e-mails med samme indhold

1. Start først dit Outlook-program.
2. Derefter skal du oprette et skabelonsvar, som du vil bruge til at besvare flere e-mails.

• Først skal du oprette en ny e-mail.
• Skriv derefter denne e-mail baseret på det, du vil svare.
• Klik derefter på "File" og vælg "Save As".
• Senere skal du indtaste et navn i den nye dialogboks "Gem som" og vælge "Outlook-skabelon" i boksen "Gem som type".
• Endelig skal du trykke på “OK” -knappen.

3. Dernæst kan du lukke e-mailen uden at gemme ændringer.
4. Derefter skal du trykke på “Alt + F11” -tasten.
5. Derefter vises Outlook VBA-editorvinduet.
6. Nu skal du finde og åbne “ThisOutlookSession” -projektet og kopiere følgende VBA-kode ind i det.

Sub Application_ItemContextMenuDisplay(ByVal CommandBar As Office.CommandBar, ByVal Selection As Selection)
    Dim objCommandBarButton As Office.CommandBarButton
 
    If (Selection.count > 1) And (Selection.Item(1).Class = olMail) Then
       Set objCommandBarButton = CommandBar.Controls.Add(msoControlButton)
 
       'Add a "Same Reply" option to the context menu
       With objCommandBarButton
           .Style = msoButtonIconAndCaption
           .Caption = "Same Reply"
           .FaceId = 355
           .OnAction = "Project1.ThisOutlookSession.SendSameReply"
       End With
    End If
End Sub

Sub SendSameReply()
    Dim strTemplate As String
    Dim objTemplateReply As Outlook.MailItem
    Dim strHTMLBody As String
    Dim objSelection As Outlook.Selection
    Dim i As Long
    Dim objReply As Outlook.MailItem
 
    'Input the name of the previously saved template
    strTemplate = InputBox("Enter the name of template message:", , "Template Reply")
    Set objTemplateReply = Application.CreateItemFromTemplate("C:\Users\Test\Documents\UserTemplates\" & strTemplate & ".oft")
    strHTMLBody = objTemplateReply.HTMLBody
 
    Set objSelection = Application.ActiveExplorer.Selection
 
    For i = objSelection.count To 1 Step -1
        Set objReply = objSelection(i).Reply
        With objReply
             .HTMLBody = strHTMLBody & objReply.HTMLBody
             .Send
        End With
    Next
End Sub

7. Endelig kan du lukke det aktuelle vindue og prøve denne makro.

• Vælg først flere e-mails på mail-listen.
• Højreklik derefter på dem.
• Vælg derefter og tryk på "Samme svar" i kontekstmenuen.
• Derefter skal du angive den skabelon, der bruges til svar.
• Efter at have indtastet navnet og trykket på "OK", sendes det samme svar til disse valgte e-mails.

Outlook er tilbøjelig til korruption

Som en almindelig bruger af Outlook har jeg været udsat for en række fejl. Derfor har jeg truffet forskellige foranstaltninger for at beskytte mine Outlook-data. På grund af det faktum, at Outlook er modtageligt for skader og nedbrud er svært at forudsige, er jeg dog nødt til at være forberedt hele tiden. For eksempel for at redde mine data så hurtigt som muligt har jeg holdt et bemærkelsesværdigt gendannelsesværktøj praktisk - DataNumen Outlook Repair. Det er i stand til rette Outlook fil uden besvær.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder sql korruption og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com