Sådan batcheksporteres flere Outlook-e-mails til ét Word-dokument via VBA

Outlook-løsninger September 29, 2025

Hvis du vil batcheksportere flere Outlook-e-mails til et enkelt word-dokument, kan du bruge VBA-koden vist i denne artikel. Det kan hjælpe dig med at udføre denne opgave på få sekunder.

Jeg har nogensinde introduceret, hvordan man konverterer en Outlook-e-mail til et Word-dokument i min tidligere artikel - "2 effektive metoder til at konvertere en Outlook-e-mail til et Word-dokument”. Imidlertid er begge de 2 midler nævnt i den pktost vil være hjælpeløs i det tilfælde, hvor du ønsker at batcheksportere mange e-mails til ét Word-dokument. Derfor vil vi her lære dig en anden måde. Læs nu videre for at få det udførligt.

Batcheksportér flere Outlook-e-mails til ét Word-dokument via VBA

Batcheksportér flere Outlook-e-mails til ét Word-dokument

  1. Til starstart med dit Outlook-program.
  2. Derefter, efter at have indtastet hovedvinduet i Outlook, skal du trykke på "Alt + F11" -tasterne.
  3. Dernæst får du adgang til Outlook VBA editor, hvor du skal åbne et tomt modul.
  4. Kopier efterfølgende VBA-koden nedenfor til det åbnede modulvindue.
Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

VBA-kode - Batcheksporter flere Outlook-e-mails til ét Word-dokument

  1. Derefter er det bedre at tilføje dette nye VBA-projekt til værktøjslinjen eller båndet Hurtig adgang.
  2. I sidste ende kan du prøve.
  • For det første skal du vælge flere Outlook-e-mails.
  • Find og klik derefter på den nyligt tilføjede makro-knap.
  • Når du bliver bedt om "Fuldfør", kan du browse til den foruddefinerede lokale mappe for at finde et nyt Word-dokument.
  • Åbn dette dokument, hvor du kan se alle de valgte e-mails er blevet eksporteret.

Hold et mægtigt genoprettelsesværktøj i nærheden

Uanset mange funktioner kan Outlook stadig ikke være immune over for fejl. Hvis du er vant til at lade fejl være i fred, mens de hober sig op, vil Outlook helt sikkert opstå. På det tidspunkt er det vigtigt at vende tilbage til et mægtigt og effektivt genoprettelsesværktøj, som f.eks DataNumen Outlook Repair. Det er velbevandret PST-rettelse. Så længe med det, behøver du ikke at være bekymret for outlook-datatab længere.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder beskadiget mdf og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com

Kommentarer er lukket.