Sådan indstilles automatisk forskellige påmindelsestider til Outlook-møder i forskellige farvekategorier

Hvis du klassificerer Outlook-møder efter farvekategorier og ønsker at indstille forskellige påmindelsestider for møder i forskellige farvekategorier, kan du henvise til denne artikel. Her vil vi lære dig at realisere det med Outlook VBA.

For eksempel deler du møder op i to grupper. Den ene er i farvekategorien "Offsite", da mødestedet er for langt væk, og den anden er i farvekategorien "Onsite", da stedet er lige her. Nu ønsker du, at Outlook automatisk kan indstille påmindelsestidspunktet for "offsite"-møder til 1 time før start og "onsite"-møder til 15 minutter før start. Med udgangspunkt i dette krav vil vi i det følgende dele en hurtig metode.

Indstil automatisk forskellige påmindelser til møder i forskellige farvekategorier

1. Start med at starte din Outlook-applikation.
2. Tryk derefter på “Alt + F11” -tasten for at få adgang til VBA-editorvinduet.
3. Derefter skal du i det efterfølgende vindue kopiere og indsætte VBA-koden nedenfor i projektet “ThisOutlookSession”.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Senere skal du klikke på underrutinen "Application_Startup" og trykke på "F5"-tasten for at køre denne makro.
5. Siden da, hver gang et nyt møde føjes til standardkalenderen, eller du ændrer et eksisterende møde, vil Outlook automatisk kontrollere kategorierne for mødet og automatisk indstille den forskellige påmindelsestid.

Fjern Outlook-fejl

Forskellige problemer kan opstå med Outlook fra tid til anden. Derfor er det ekstremt vigtigt for brugerne at lære, hvordan man håndterer Outlook-problemer. Til at starte med bør du lave regelmæssige sikkerhedskopier af Outlook-data. Desuden anbefales det, hvis det er overkommeligt, at have en effektiv sikkerhedskopi. Outlook reparation værktøj i nærheden, f.eks DataNumen Outlook Repair. Det kan scanne din PST-fil for at finde ud af Outlook-problemer og derefter løse dem med lethed.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder sql opsving og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com