Sådan flyttes e-mails automatisk med specifikke CC-modtagere i Outlook

I virkeligheden håber de fleste af jer måske på at oprette en Outlook-regel til automatisk at flytte e-mails med specifikke CC-modtagere. Men Outlook-regler understøtter ikke kontrol af CC-modtagere. Så denne artikel vil lære dig, hvordan du gør det med Outlook VBA.

Det er selvfølgelig umuligt for dig at oprette en Outlook-regel for at søge efter specifikke CC-modtagere. Som vist i det følgende skærmbillede, for modtagne e-mails, kan du kun kontrollere, om dit eget navn er i CC-feltet. På samme måde er der endda ingen regelbetingelser for at markere CC-boksen for sendte e-mails.

Derfor, hvis du vil konfigurere Outlook til automatisk at flytte e-mails med specifikke CC-modtagere, skal du søge andre midler. Derefter. her vil vi lære dig, hvordan du opnår det ved hjælp af Outlook VBA.

Flyt automatisk de sendte e-mails med specifikke CC-modtagere

1. Drej først til fanen “Udvikler” og klik på “Visual Basic” -knappen.
2. Åbn derefter “ThisOutlookSession” -projektet, og kopier følgende VBA-koder ind i det.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

3. Derefter skal du fortsætte med at underskrive denne kode og ændre makroindstillingerne som normalt.
4. Endelig kan du forlade vinduet “Visual Basic”. Derefter flyttes e-mails med de specifikke CC-modtagere til den angivne mail-mappe.

Flyt de modtagne e-mails automatisk med specifikke CC-modtagere

Nu hvor ovenstående VBA-kode sigter mod at flytte sendte e-mails med specifikke CC-modtagere. Hvis du vil kigge efter specifikke CC-modtagere i modtagne e-mails og derefter flytte den, skal du bruge følgende koder i stedet.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

Hold godt forberedt på Outlook-korruption

Selvom Outlook er funktionsrige, kan det stadig ikke være immun over for korruption. Så du skal være opmærksom på alle de potentielle risici. Utvivlsomt skal det kritiske trin være at foretage en konsekvent og opdateret sikkerhedskopi af Outlook-data. Desuden skal du holde en korrupte Outlook opsving værktøj i nærheden. Det vil være nyttigt, hvis både sikkerhedskopierne og Scanpst.exe mislykkes.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder reparere SQL Server mdf-filfejl og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com