4 metoder til at udtrække tabeller fra et Word-dokument til et andet

I denne artikel er vi glade for at vise dig med 4 metoder til at udtrække flere tabeller fra et Word-dokument til et andet.

Tabellen er most brugt betyder, at vi bruger til at opbevare tabeloplysninger. Det arrangerer data i rækker og kolonner, hvilket giver læserne et klart overblik over al information. Et langt dokument kan indeholde mange tabeller, så der er behov for at eksportere dem til et nyt dokument til forskellige formål.

Her er vores 4 tilgange.

Metode 1: Batcheksport af alle tabeller fra et dokument til et andet

1. Første og foremost, tryk på “Alt + F11” for at udløse VBA-editoren i Word.
2. Klik derefter på "Normal" -projektet og derefter på fanen "Indsæt".
3. Vælg "Module" i rullemenuen.
4. Og dobbeltklik for at åbne modulet og frembringe redigeringsområdet på højre side.
5. Kopier og indsæt nu følgende makro der:

Sub ExtractTablesFromOneDoc()
  Dim objTable As Table
  Dim objDoc As Document
  Dim objNewDoc As Document
  Dim objRange As Range
 
  Set objDoc = ActiveDocument
  Set objNewDoc = Documents.Add
 
  For Each objTable In objDoc.Tables
    objTable.Range.Select
    Selection.Copy
 
    '  Paste tables to new document in rich text format.
    Set objRange = objNewDoc.Range
    objRange.Collapse Direction:=wdCollapseEnd
    objRange.PasteSpecial DataType:=wdPasteRTF
    objRange.Collapse Direction:=wdCollapseEnd
    objRange.Text = vbCr
  Next objTable
 
End Sub

6. Klik til sidst på "Kør".

Denne makro udpakker også begge tabeller og deres billedtekster.

Metode 2: Uddrag en specifik tabel fra et dokument

I tilfælde af at der er mange tabeller i dit dokument, men du skal sende en bestemt tabel til nogen. Så vil følgende makro hjælpe dig meget.

1. Først skal du installere og køre makro ved at følge trinene i metode 1.
2. For det andet skal du udskifte makroen med denne:

Sub ExtractSpecificTables()
  Dim objTable As Table
  Dim objDoc As Document
  Dim objNewDoc As Document
  Dim objRange As Range
  Dim strTable As String
 
  strTable = InputBox("Enter the table number: ")
  Set objDoc = ActiveDocument
  Set objNewDoc = Documents.Add
 
  objDoc.Tables(strTable).Range.Select
  Selection.Copy
 
  Set objRange = objNewDoc.Range
  objRange.Collapse Direction:=wdCollapseEnd
  objRange.PasteSpecial DataType:=wdPasteRTF
 
End Sub

3. Nu vil der være en inputboks, der dukker op.
4. Indtast et tabelnummer, og klik på “OK”.

Metode 3: Batch-udtræk alle tabeller fra flere dokumenter

1. Til start med, arranger alle filer i en mappe.
2. Installer og kør derefter en makro med nøjagtige ovenstående instruktioner.
3. Udskift makro med denne:

Sub ExtractTablesFromMultiDocs()
  Dim objTable As Table
  Dim objDoc As Document, objNewDoc As Document
  Dim objRange As Range
  Dim strFile As String, strFolder As String
 
  '  Initialization
  strFolder = InputBox("Enter folder address here: ")
  strFile = Dir(strFolder & "\" & "*.docx", vbNormal)
 
  Set objNewDoc = Documents.Add
 
  '  Process each file in the folder.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & "\" & strFile)
    Set objDoc = ActiveDocument
 
    For Each objTable In objDoc.Tables
      objTable.Range.Select
      Selection.Copy
 
      Set objRange = objNewDoc.Range
      objRange.Collapse Direction:=wdCollapseEnd
      objRange.PasteSpecial DataType:=wdPasteRTF
      objRange.Collapse Direction:=wdCollapseEnd
      objRange.Text = vbCr
    Next objTable
 
    objDoc.Save
    objDoc.Close
    strFile = Dir()
  Wend
 
End Sub

4. Indtast nu mappeadressen, hvor du gemmer dine dokumenter, i anmodningsfeltet, og klik på “OK”.

Metode 4: Kopier tabeller manuelt

Men hvis du ikke har det godt med VBA, har du det fint at udføre jobbet manuelt, så længe der er et begrænset antal tabeller.

1. Klik først på plustegnet i øverste venstre hjørne for at vælge tarfå bord.
2. Tryk derefter på "Ctrl + C" for at kopiere det.
3. Åbn derefter et nyt dokument.
4. Og tryk på "Ctrl + V" for at indsætte tabellen i nyt dokument.
5. Husk at gemme det nye dokument.

Håndteres med dokumentproblemer

Så længe vi fortsætter med at bruge Word, vil det altid være Ordskade. Frygt dog ikke mere. Det er ikke et ufixabelt problem længere. Med et kvalificeret gendannelsesværktøj har du en stor chance for at hente alle dine værdifulde data.

Forfatter Introduktion:

Vera Chen er en datagendannelsesekspert i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder korrupt xlsx og pdf produkter til reparation af software. For mere information besøg www.datanumen.com