3 måder til hurtigt at indsætte sektionsbrud i dit Word-dokument

I denne artikel vil vi fokusere på at vise dig 3 måder til hurtigt at indsætte sektionsskift i dit Word-dokument.

Sektionsskift er nyttige til at opdele et dokument i sektioner, kapitler osv. Desuden er at indsætte sektionsskift en uundværlig del af at sætte forskellige sidehoveder eller sidefødder på forskellige sider.Indsæt hurtigt sektionsopdelinger i dit Word-dokument

Normalt bliver vi nødt til at navigere til siden og finde markøren i den rigtige position. Klik derefter på "Sidelayout" og "Breaks". Og vælg derefter en sektionsskifttype på rullemenuen. Sådan en procedure kan nogle gange være kedelig. Derfor vil vi redde dig fra den sædvanlige rutine og vedtage en hurtig og beskidt løsning.Klik på "Sidelayout"->Klik på "Pause"->Vælg en sektionsskifttype

Metode 1: Indsæt et afsnitsskift på en bestemt side

  1. Først og fremmest skal du trykke på "Alt + F11" i Word for at starte VBA-editoren.
  2. Opret derefter et nyt modul ved at klikke på “Normal” i venstre kolonne.
  3. Klik derefter på "Indsæt" -fanen på menulinjen.
  4. Og vælg "Modul" i rullemenuen "Indsæt".Klik på "Normal" -> Klik på "Indsæt" -> Klik på "Modul"
  5. Dobbeltklik på det nye modul for at åbne det.
  6. Indsæt følgende makro på kodningsområdet:
Sub InsertBreakOnSpecificPage()
  Dim strPageNum As String
  Dim nPageNum As Integer
 
  strPageNum = InputBox("Enter a page number: ")
  nPageNum = Int(strPageNum)
 
  Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nPageNum
  ActiveDocument.Bookmarks("\page").Range.Select
  Selection.Collapse wdCollapseEnd
  Selection.InsertBreak Type:=wdSectionBreakContinuous
End Sub
  1. Klik nu på "Kør" eller tryk på "F5" for at udføre koder.Indsæt makro-> Klik på "Kør"
  2. Indtast derefter sidetallet for målsiden i feltet. Klik på "OK" for at fortsætte.Indtast et sidenummer -> Klik på "OK"

Indtil videre har du indsat et afsnitsskift i slutningen af ​​side 2.

Bemærk:

Hvis du ønsker at adskille flere på hinanden følgende sider som et afsnit med brug af afsnitsskift, skal du indsætte afsnitsskift to gange, et i slutningen af ​​sidste side af forrige afsnit og et i slutningen af ​​sidste side af dette nye afsnit .

I et sådant tilfælde, mens du indsætter den første pause, bør du huske at indtaste det korrekte tal, som er sidetallet på sidste side i forrige afsnit.

Metode 2: Indsæt et afsnitsskift på hver side af et dokument

  1. For det første skal du installere og køre en makro ved at følge ovenstående trin nøjagtigt.
  2. Udskift derefter makroen med denne:
Sub InsertBreakOnEachPage()
  Dim nTotalPageNumber As Integer
 
  For nTotalPageNumber = 1 To Selection.Information(wdNumberOfPagesInDocument)
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nTotalPageNumber
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Collapse wdCollapseEnd
    Selection.InsertBreak Type:=wdSectionBreakContinuous
  Next
End Sub

Denne makro indsætter et afsnitsskift i slutningen af ​​hver side i det aktuelle dokument.

Metode 3: Indsæt et afsnitsskift på hver side af flere dokumenter

  1. Til at begynde med skal du placere alle måldokumenter i den samme mappe.
  2. Installer og kør derefter makro med korrekte instruktioner.
  3. Denne gang skal du bruge disse koder:
Sub InsertBreaksIntoMultiDoc()
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nTotalPageNumber As Integer
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "No folder is selected! Please select the target folder."
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    For nTotalPageNumber = 1 To Selection.Information(wdNumberOfPagesInDocument)
      Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nTotalPageNumber
      Application.Browser.Target = wdBrowsePage
      ActiveDocument.Bookmarks("\page").Range.Select
      Selection.Collapse wdCollapseEnd
      Selection.InsertBreak Type:=wdSectionBreakContinuous
    Next
    objDoc.Save
    objDoc.Close
    strFile = Dir()
  Wend
End Sub
  1. Makroen skal udløse vinduet "Gennemse". Vælg den mappe, hvor du opbevarer dokumenter, og klik på "OK".Vælg en mappe-> Klik på "OK"

Processen må ikke tage mere end et par sekunder.

Praktisk værktøj til dokumentkorruption

Det er en frustrerende oplevelse at støde på beskadigede dokumenter. I et sådant scenarie, et godt og pålideligt værktøj, der kan hjælpe reparere Word dokumenter skal kunne lindre ens angst meget. Derfor skal du være yderst forsigtig, når du vælger et reparationsværktøj. Et utilstrækkeligt hjælpeprogram kan forårsage yderligere skade.

Forfatter Introduktion:

Vera Chen er en datagendannelsesekspert i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder Excel-gendannelse og pdf produkter til reparation af software. For mere information besøg www.datanumen.com

Kommentarer er lukket.