2 hurtige måder at finde eller slette sætninger indeholdende specifik tekst i dit ord

I denne artikel vil vi tilbyde dig 2 hurtige måder at finde eller slette sætninger indeholdende specifik tekst i dit Word.

Det er kendt af alle, at vi kan bruge funktionen "Søg og erstat" i Word til nemt at finde alle forekomster af bestemte ord. Så har vi ingen problemer med at fremhæve, erstatte eller fjerne dem. Som du kan se, er målet et ord eller en sætning. I dag er vi dog glade for at kunne fortælle dig den makromæssige måde at finde eller slette sætninger, der indeholder en bestemt tekst.

Metode 1: Find eller slet sætninger, der indeholder specifik tekst

1. Til at begynde med skal du trykke på “Alt + F11” for at udløse VBA-editoren i Word.
2. Opret derefter et nyt modul ved at klikke på “Normal”.
3. Klik derefter på "Indsæt" og vælg "Modul" for at få et nyt.
4. Og åbn modulet med dobbeltklik.
5. Indsæt nu følgende koder:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Klik derefter på "Kør".
7. Der vil være et inputfelt, der beder dig om at indtaste tekst. Skriv bare den almindelige tekst, som alle sætninger indeholder. Klik på “OK”.
8. Derefter skal du se en sætning indeholdende teksten i markering med en meddelelsesboks, der beder om. Klik på "Ja" for at slette sætningen og "Nej" for at beholde den.
9. Efter bekræftelsen er den næste sætning med den angivne tekst valgt. Og der er også bekræftelsesfeltet. Makroen tager dig med til at gå trin for trin gennem hele dokumentet, finde målsætninger og bede om din bekræftelse hver gang.

Metode 2: Find eller slet sætninger, der indeholder enhver tekst på en liste

Med makroen i metode 1 kan du kun søge efter et ord eller en sætning ad gangen. Bestemt kan du køre makroen gentagne gange for at søge efter finde flere forekomster af ord eller sætninger. For at imødekomme behovet for flere søgninger giver vi dig en anden makro.

1. Først skal du placere alle måltekster i et nyt dokument. Sørg for, at hvert tekststykke optager ét afsnit uden mellemrum. Luk og gem dokumentet.
2. Næste installation og kørsel af en makro med de nøjagtige trin i metode 1.
3. Udskift derefter makro med denne:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Nu åbnes vinduet "Gennemse". Vælg det netop gemte dokument, og klik på "Åbn".
5. Følgende procedure er den samme som i metode 1.

Fremgangsmåde til at håndtere korrupte dokumenter

Tab af værdifulde data er absolut ødelæggende. Det kan endda lade din virksomhed stå på spil. For at undgå en sådan frustration skal du få fat i en Ordrettelse værktøj så hurtigt som muligt. Et sådant værktøj vil hjælpe dig med at vinde kampen med dokumentkorruption.

Forfatter Introduktion:

Vera Chen er en datagendannelsesekspert i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder rette Excel og pdf produkter til reparation af software. For mere information besøg www.datanumen.com