2 hurtige måder at udtrække sektioner fra dit Word-dokument

I denne artikel tilbyder vi dig 2 hurtige og nemme måder at udtrække sektioner fra dit Word-dokument til et andet eller flere.

Det sker ret ofte at udtrække indhold fra et dokument til et andet. Og i vores tidligere artikel har vi diskuteret, hvordan man udtrækker sider fra dokumentet. For detaljeret information kan du henvise til denne artikel: 2 hurtige måder at udtrække individuelle sider fra dit Word-dokument

I dag viser vi dig, hvordan du udtrækker efter sektion.    

Metode 1: Uddrag nuværende sektion til et nyt dokument

1. Først og fremmest skal du placere markøren i a tarfå sektion.
2. Tryk derefter på “Alt + F11” for at påkalde VBA-editor i Word.
3. Klik derefter på venstre kolonne på “Normal”.
4. Klik på "Indsæt" på menulinjen.
5. Vælg derefter “Modul” i rullemenuen.
6. Dobbeltklik for at åbne det nye modul og indsætte følgende koder der:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Klik derefter på "Kør" i menulinjen eller tryk på "F5".
8. Derefter vises vinduet "Gennemse". Vælg et sted at gemme det nye dokument, og klik på “OK”.
9. Og i feltet "Filnavn" skal du indtaste navnet på den nye fil og klikke på "OK".

Nu har du udtrukket sektionen til et nyt dokument.

Metode 2: Uddrag hver sektion i dokumentet til individuelle nye

Denne måde kan hjælpe dig med batchbehandling af alle sektioner i et dokument. Selvfølgelig har vi også brug for en makro.

1. Til at begynde med skal du åbne tarfå dokument.
2. Følg derefter trin i metode 1 for at installere og køre en makro.
3. Kun denne gang erstatter denne makro med denne:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. I vinduet "Gennemse" skal du stadig vælge en lagersti og klikke på "OK".

Ret irriterende ordfejl

Det er almindeligt at støde på nogle Word-fejl, mens du bruger det. Irriterende kan det være, vi skal tage os tid til det genoprette ord så hurtigt som muligt. Fordi jo længere vi udsætter det, desto strengere kan datatabet være. Derfor foreslås det at få fat i et reparationsværktøj på forhånd.

Forfatter Introduktion:

Vera Chen er en datagendannelsesekspert i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder beskadigede xls og pdf produkter til reparation af software. For mere information besøg www.datanumen.com