2 hurtige måder at udtrække individuelle sider fra dit Word-dokument

I dagens indlæg vil vi dele 2 hurtige måder at udtrække individuelle sider fra dit Word-dokument med dig.

Nogle gange i et Word-dokument kan hver side indeholde ganske uafhængigt indhold, såsom en tabel. Og du bliver sandsynligvis nødt til at sende forskellige tabeller til forskellige mennesker. Derefter bliver du nødt til at gemme hver tabel, der er på hver side, som en separat fil.

Den første idé, der opstår i vores sind, skal være den klassiske copy-and-paste. Alligevel kan alt, hvad der involverer valg, være irriterende nogle gange, for at trække og vælge kan nemt gøre ender uden valg overhovedet. Af denne grund anbefaler vi dig to hurtige metoder ved hjælp af makro til at udføre jobbet.

Metode 1: Uddrag den aktuelle side, og gem den som et nyt dokument

1. Først og fremmest skal du placere din markør på den side, du vil udtrække.
2. Klik på fanen "Udvikler", og klik derefter på "Visual Basic" for at påkalde VBA-editoren. Hvis “Udvikleren” ikke er aktiveret, skal du blot trykke på “Alt + F11” i stedet.
3. For det andet skal du gå til “Normal” -projektet ved at klikke på det.
4. Klik derefter på fanen "Indsæt", og vælg "Modul".
5. Dobbeltklik på det nye modul for at åbne redigeringsområdet.
6. Indsæt derefter følgende koder der:

Sub SaveCurrentPageAsANewDoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim strFileName As String
  Dim strFolder As String
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
  strFileName = InputBox("Enter file name here: ")
 
  '  Copy current page.
  objDoc.Bookmarks("\Page").Range.Select
  Selection.Copy
 
  '  Open a new document to paste the selection.
  Set objNewDoc = Documents.Add
  Selection.Paste
 
  objNewDoc.SaveAs FileName:=strFolder & "\" & strFileName & ".docx"
  objNewDoc.Close
End Sub

7. Til sidst skal du klikke på “Kør” -knappen.

Nu vil der være 2 inputbokse. Indtast stien, hvor du vil gemme det nye dokument, i det første indtastningsfelt. Og indtast det nye dokumentnavn på det andet.

Metode 2: Uddrag hver side, og gem den som et nyt dokument

Den følgende makro giver dig mulighed for at udtrække hver enkelt side i et dokument.

1. For det første skal du trykke på "Ctrl + Home" for at gå til begyndelsen af ​​dit dokument.
2. Følg derefter de samme trin i metode 1 for at installere og køre en makro.
3. Denne gang erstatter makroen med denne:

Sub SaveEachPageAsADoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim nPageNumber As Integer
  Dim strFolder As String
  Dim objFileName As Range
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
 
  '  Copy each page in the document to paste it into a new one.
  For nPageNumber = 1 To ActiveDocument.ComputeStatistics(wdStatisticPages)
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Copy
 
    Set objNewDoc = Documents.Add
    Selection.Paste
 
    '  Save new doc with the name of "Page" & nPageNumber and get the first 20 characters of the new doc as part of the file name.
    Set objFileName = objNewDoc.Range(Start:=0, End:=20)
    objNewDoc.SaveAs FileName:=strFolder & "\" & "Page " & nPageNumber & " " & objFileName & ".docx"
    objNewDoc.Close
    Application.Browser.Next
  Next nPageNumber
End Sub

Håndter ordproblemer

Der er og vil altid være forskellige Word-problemer. Pointen er at lære at løse dem korrekt. Den mest anbefalede måde er selvfølgelig at få en sofistikeret Word opsving værktøj. Du skal gribe hvert minut for at gendanne dine data, før det er for sent.

Forfatter Introduktion:

Vera Chen er en datagendannelsesekspert i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder korrupt xlsx og pdf produkter til reparation af software. For mere information besøg www.datanumen.com