Как бързо да експортирате общото време, прекарано в срещите в Outlook във всяка цветова категория

Ако искате да създадете отчет за общото време, което отделяте за срещи във всяка цветна категория, можете да използвате метода, представен в тази статия. Може да ви помогне да постигнете това бързо, без да е необходимо да броите ръчно.

Много потребители са свикнали да записват повечето си дейности в календара на Outlook. Също така, за да ги управляват и разграничават по-лесно, те присвояват категории на всяка от тях. В този случай някои потребители биха искали да генерират отчет, показващ общото време, прекарано в елементите от календара във всяка цветова категория. Без съмнение е трудно да се брои и въвежда ръчно. Затова тук ще споделим начин, по който може да се изпълни тази задача с едно просто щракване.

Експортирайте общото време, изразходвано за срещите във всяка цветова категория

1. На първо място стартирайте приложението си Outlook.
2. След това, след като влезете в прозореца на Outlook, можете да докоснете клавишните бутони „Alt + F11“.
3. Впоследствие ще получите достъп до прозореца „Microsoft Visual Basic for Applications“.
4. След това ще трябва да активирате „Microsoft Excel Object Library“. Можете да щракнете върху „Tools“ > „Reference“, за да го направите.
5. След това трябва да намерите и отворите модул, който не се използва.
6. След това трябва да копирате следния VBA код в този модул.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Най-накрая можете да задействате този макрос, без значение чрез щракване върху иконата „Изпълни“ в лентата с инструменти или натискане на бутона „F5“.
8. След това ще бъдете помолени да изберете конкретен календар.
9. След като изберете и натиснете „OK“, макросът ще продължи да се изпълнява. След като приключи, ще има нов Excel файл, който се показва на заден план.
10. Имате достъп до него. Ще изглежда като следната екранна снимка:

Внимавайте за потенциални заплахи около вашия Outlook

Потребителите на Outlook трябва да внимават за всички потенциални рискове, включително неизвестни прикачени файлове към имейли, вградени връзки и човешки грешки. В противен случай вашият Outlook може да се повреди по всяко време. Също така правенето на редовни резервни копия на данни в Outlook и поддържането на специализиран инструмент за поправка са въпроси от необходимост. DataNumen Outlook Repair е един от най-препоръчителните инструменти за поправка. Той може ремонт на Outlook проблеми за миг.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително повреден mdf и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com