Как бързо да прикачите последния модифициран файл в папка на Windows към вашия имейл в Outlook

Понякога може да искате бързо да намерите и прикачите последния модифициран файл в конкретна папка на Windows към имейл на Outlook. В този случай можете да използвате метода, представен в тази статия.

Някои потребители искат Outlook бързо да открива и добавя последния променен файл в папка на Windows към имейл, като например най-скоро създаден, променен или запазен файл. Outlook обаче не предлага такава директна и вградена функция. Затова по-долу ще представим част от VBA код, който може да го реализира лесно.

Прикачете последния модифициран файл в папка на Windows към имейл

1. В самото начало трябва да стартирате приложението си Outlook.
2. След това, след като влезете в главния прозорец на Outlook, можете да натиснете бутоните на клавишите „Alt + F11“.
3. След това ще имате достъп до прозореца на редактора на Outlook VBA успешно.
4. Впоследствие трябва да намерите и отворите модул, който не се използва.
5. И след това копирайте и поставете следния VBA код в този прозорец на модула.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. След това можете да излезете от текущия прозорец на редактора на VBA и да продължите да добавяте новия макрос към лентата с инструменти за бърз достъп или лентата на прозореца за съобщения.
7. По-късно трябва да промените нивото на защита на макроса на Outlook на ниско.
8. В крайна сметка можете да опитате.

• Първо, създайте и съставете нов имейл на Outlook, както обикновено.
• След това натиснете бутона за макрос в лентата с инструменти за бърз достъп, като изображението по-долу:
• След това ще трябва да изберете изходна папка на Windows и натиснете „OK“.
• Ако има такъв файл в избраната папка на Windows, ще получите подкана като следната екранна снимка:
• Когато натиснете „Да“, този файл ще бъде прикачен наведнъж.

Решаване на проблеми с Outlook възможно най-скоро

Всеки път, когато срещнете някакви проблеми с Outlook, препоръчително е да ги разрешите възможно най-скоро. В тази ситуация по-добре подгответе солидна Поправка на Outlook инструмент предварително, като DataNumen Outlook Repair. Той е в състояние да коригира PST грешки и да спаси ефективно данните ви в Outlook.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително повреден mdf и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com