Как да покажете съответните възрасти на лицата за всички събития за рожден ден в списъчен изглед на календара на Outlook

Някои потребители биха искали да видят и възрастта на съответния човек, когато преглеждат събитие за рожден ден в календара. Затова в тази статия ще споделим метод за лесно реализиране на тази идея.

Когато добавите информация за рожден ден към контакт, Outlook автоматично ще създаде събитие за рожден ден в календара. При това обстоятелство всеки път, когато видите събития за рождени дни в календара, може също да искате да получите възрастта на съответните хора. Затова тук ще ви представим начин да го реализирате.

Показване на съответните възрасти на лицата за всички рождени дни в изглед на списък

1. В самото начало стартирайте Outlook VBA редактор.
2. След това копирайте следния код в модул.

Sub ShowAgesOfBirthdayEventsListView()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Process All Calendar Folders in Your Outlook
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olAppointmentItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCalendar As Outlook.Folder)
    Dim i As Integer
    Dim objItem As Object
    Dim objBirthdayEvent As Outlook.AppointmentItem
    Dim dStart, dBirth As Date
    Dim nAge As Integer
    Dim objNewProperty As Outlook.UserProperty
    Dim objSubCalendar As Outlook.Folder

    For i = objCalendar.Items.Count To 1 Step -1
        Set objItem = objCalendar.Items.Item(i)
        'Add "Age" Property to Birthday Events
        If (objItem.MeetingStatus = olNonMeeting) And (objItem.IsRecurring = True) And (Right(objItem.Subject, 11) = "'s Birthday") Then
           Set objBirthdayEvent = objItem
           dStart = objBirthdayEvent.Start
 
           'Count Age
           dCurrentBirthday = DateSerial(Year(Now), Month(dStart), Day(dStart))
           nAge = DateDiff("yyyy", dStart, dCurrentBirthday)
 
           Set objNewProperty = objBirthdayEvent.UserProperties.Find("Age", True)
           If objNewProperty Is Nothing Then
              Set objNewProperty = objBirthdayEvent.UserProperties.Add("Age", olText, True)
           End If
 
           objNewProperty.value = nAge
           objBirthdayEvent.Save
        End If
    Next
 
    'Process All Sub-Calendar Folders Recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call ProcessFolders(objSubCalendar)
       Next
    End If
End Sub

3. След това поставете курсора в първата подпрограма и натиснете „F5“, за да стартирате този макрос.
4. Когато макросът приключи, излезте от редактора на VBA и отворете папка с календар.
5. След това отидете в раздела „Изглед“ и щракнете върху „Промяна на изгледа“ > „Списък“.
6. След това щракнете върху бутона „Преглед на настройките“.
7. В изскачащия диалогов прозорец изберете „Колони“.
8. След това в следващия диалогов прозорец на „Показване на колони“ изберете „Дефинирани от потребителя полета в папка“ от списъка „Избор на налични полета от“.
9. По-късно изберете „Възраст“ в полето „Налични колони“ и щракнете върху бутона „Добавяне ->“.
10. В крайна сметка щракнете върху поредица от „OK“, докато се върнете към списъка с елементи от календара.
11. Сега в списъка можете да видите възрастта на хората за всички събития за рожден ден, както е показано на следващата фигура.

Коригирайте компрометирания файл на Outlook

Може да изпаднете в паника, когато срещнете корумпиран Outlook файл, който съдържа много от вашите ценни имейли и графици. Въпреки че този проблем е доста отчаян, все пак трябва незабавно да се успокоите и да обмислите ефективни мерки. Ако продължавате да се притеснявате, ситуацията може да става все по-лоша и по-лоша. Всъщност има множество начини и помощни програми, които могат да поправят повредения файл, като инструмент за поправка на входящата кутия и по-стабилен и опитен инструмент, като DataNumen Outlook Repair.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително SQL Server фиксира и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com