Как да зададете различно време за напомняне по подразбиране за различни видове маркирани елементи във вашия Outlook

По подразбиране Outlook автоматично ще използва времето за напомняне по подразбиране за задачи за всички видове маркирани елементи. И все пак, ако искате да използвате различно време за напомняне за маркирани елементи въз основа на типа на елемента, можете да се обърнете към метода, представен в тази статия.

Outlook ви позволява да зададете време за напомняне по подразбиране за всички маркирани елементи, независимо от типа на елемента. Можете да отидете в менюто „Файл“ и да щракнете върху „Опции“. След това в прозореца „Опции на Outlook“ можете да видите опцията „Време за напомняне по подразбиране“ в раздела „Задачи“, както е показано на следващата екранна снимка.

Въпреки това, повечето потребители се надяват да използват различно време за напомняне за различните видове маркирани елементи, като например „9:00“ за маркирани имейли и „17:30“ за маркирани контакти. Сега, по-долу, ще се съсредоточим върху този пример, за да представим метод.

Задайте различно време за напомняне по подразбиране за различни видове маркирани елементи

1. За начало стартирайте приложението Outlook.
2. След това отворете редактора на Outlook VBA с препратка към „Как да стартирате VBA код във вашия Outlook".
3. В следващия прозорец „Microsoft Visual Basic за приложения“, копирайте следния код в проекта „ThisOutlookSession“.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. След това рестартирайте Outlook, за да активирате този макрос.
5. Отсега нататък всеки път, когато маркирате имейл, времето за напомняне ще бъде зададено на „10:00“ на крайната дата за маркиране.
6. И когато маркирате контакт, времето за напомняне ще бъде зададено на „17:30“ на крайната дата за маркиране.

Справете се с проблемите на Outlook гъвкаво

Можете да срещнете всякакви проблеми в Outlook. Така че трябва да научите някои мерки за справяне с тях предварително. Например, ако вашият Outlook често се рестартира, трябва да поправите Office или да деактивирате добавките на трети страни и т.н. Или ако вашият Outlook PST файл е компрометиран, първо можете да опитате... инструмент за ремонт на входящата кутия. Когато се провали, можете да продължите да прибягвате до мощен външен инструмент, като DataNumen Outlook Repair.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително mdf възстановяване и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com