Как групово да се отварят всички хипервръзки с конкретен домейн във вашия имейл в Outlook

Когато разглеждате имейл на Outlook, който съдържа много хипервръзки в тялото, понякога може да пожелаете бързо да отворите хипервръзките само с определен домейн. Тук ще споделим метод за групово отваряне на такива хипервръзки.

Сблъсквайки се с множество хипервръзки в един имейл, може да се надявате да проверите някои от тях, вместо всички. Например бихте искали само да отваряте групово хипервръзките с определен домейн. Като цяло трябва да щракнете един по един, за да ги отворите. Това е много обезпокоително. Следователно в следващите неща ще ви научим на по-удобен начин.

Партидно отваряне на всички хипервръзки с конкретен домейн в имейл

1. За начало, достъпете редактора на Outlook VBA съгласно „Как да стартирате VBA код във вашия Outlook".
2. Впоследствие, в прозореца „Microsoft Visual Basic for Applications“, активирайте препратката към „MS Word Object Library“ с препратка към „Как да добавите препратка към библиотека с обекти във VBA".
3. След това копирайте следния VBA код в неизползван модул или проект.

Sub BatchOpenHyperlinksWithSpecificDomain()
    Dim objMail As MailItem
    Dim objMailDocument As Word.Document
    Dim objHyperlink As Word.Hyperlink
    Dim objDictionary As Object
    Dim i As Integer
    Dim varHyperlinks As Variant
    Dim varHyperlink As Variant
    Dim objInternetExplorer As Object
 
    'Get the source email
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
    Set objMailDocument = objMail.GetInspector.WordEditor
    For Each objHyperlink In objMailDocument.Hyperlinks
        If InStr(1, objHyperlink.Address, "www.datanumen.com") > 0 Then
           'Add Hyperlinks to Dictionary
           If objDictionary.Exists(objHyperlink.Address) = False Then
              objDictionary.Add objHyperlink.Address, 1
           End If
        End If
    Next
 
    'Batch Open Hyperlinks on different tabs in same Internet Explorer window
    Set objInternetExplorer = CreateObject("InternetExplorer.Application")
    varHyperlinks = objDictionary.Keys
    For i = LBound(varHyperlinks) To UBound(varHyperlinks)
        varHyperlink = varHyperlinks(i)
 
        If i = 0 Then
           objInternetExplorer.Visible = True
           objInternetExplorer.navigate varHyperlink
        Else
           objInternetExplorer.navigate varHyperlink, CLng(2048)
        End If
    Next
End Sub

4. След това добавете този макрос към лентата с инструменти за бърз достъп или лентата.
5. И накрая, направете следните стъпки, за да опитате.

• Първо изберете или отворете имейл на Outlook.
• След това щракнете върху бутона за макрос.
• Веднага хипервръзките с предварително дефинирания домейн в имейла ще бъдат партидно отворени в Internet Explorer, както е показано на следното изображение:

Отървете се от дразнещата корупция в Outlook

Въпреки че Outlook е податлив на грешки и корупция, всъщност, стига да внимавате за всички рискове, можете да избягате от тях с лекота. Например трябва редовно да правите резервни копия на данни за Outlook. Освен това трябва да внимавате за подозрителните имейли, които могат да съдържат вируси. Не на последно място, по-добре подгответе Поправка на Outlook полезност, като DataNumen Outlook Repair. Той е в състояние да ви помогне в случай на корупция в Outlook.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително повредени SQL Server и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com