Как да маркирам автоматично срещите за уикенда като частни в Outlook

За мost потребители, срещите, насрочени за уикенда, обикновено са частни. Следователно те искат Outlook автоматично да маркира и показва такива срещи като частни. В тази статия ще направим това с малко скриптове.

За да може по-лесно да се прави разлика между бизнес и частни срещи, Outlook позволява на потребителите да маркират срещи като частни. По този начин ще намерите доста удобно и лесно да отпечатвате календар без лични срещи. В тази ситуация може да пожелаете вашият Outlook автоматично да разпознава и маркира определени срещи като частни. Например обикновено срещите през уикенда са частни, поради което искате да оставите на Outlook автоматично да ги маркира като частни. По-нататък ще ви насочим да го постигнете.

Автоматично маркиране на срещите за уикенда като частни

1. Първо стартирайте редактора на Outlook VBA според „Как да стартирате VBA код във вашия Outlook".
2. След това в прозореца „Microsoft Visual Basic for Applications“ поставете следния код в проекта „ThisOutlookSession“.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olAppointment Then
       Set objAppointment = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objAppointment_Open(Cancel As Boolean)
    Call MarkWeedendAppointmentPrivate(objAppointment)
End Sub

Private Sub objAppointment_PropertyChange(ByVal Name As String)
    If Name = "Start" Or Name = "End" Then
       Call MarkWeedendAppointmentPrivate(objAppointment)
    End If
End Sub

Private Sub MarkWeedendAppointmentPrivate(ByVal objAppointment As Outlook.AppointmentItem)
    Dim dStartDate As Date
 
    dStartDate = Format(objAppointment.Start, "Short Date")
 
    'If the appointment start falls on weekend
    Select Case Weekday(dStartDate)
           Case 7, 1
                'Mark it private
                objAppointment.Sensitivity = olPrivate
    End Select
End Sub

3. След това, резtart Outlook, за да активирате макроса.
4. Отсега нататък всеки път, когато създавате нова среща или променяте съществуваща среща за уикенда, Outlook автоматично ще я маркира като частна.

Решаване на досадни проблеми с Outlook

Възможно е да сте срещнали някои проблеми при работа с Outlook, като неочаквано замразяване на приложения, изскачащи съобщения за грешки и т.н. Когато ги страдате, бихте се притеснили. Моля, успокой се! Паниката няма да помогне на нищо, но ще влоши случая. На първо място можете да проверите дали имате достъп до PST файла както обикновено. Ако е така, трябва да поправите PST файла, което може да се извърши чрез инструмент за ремонт на входящата кутия или по-мощен външен инструмент, като DataNumen Outlook Repair.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително mdf ремонт и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com