Как да изпращате групово всички файлове в папка на Windows чрез отделни имейли на Outlook

Ако искате да изпратите всички файлове в папка на Windows чрез отделни имейли на Outlook на някого, можете да използвате метода, представен в тази статия. Използва VBA код, който е доста ефективен.

След като прочетох предишната ми статия - „3 бързи метода за прикачване на всички файлове в локална папка към имейл на Outlook”, Някои потребители искат да изпращат всички файлове в локална папка чрез отделни имейли. По стандарт трябва да създавате имейли и да прикачвате файловете един по един. Това е доста обезпокоително. Затова в следващите стъпки ще ви представим по-ефективен начин.

Пакетно изпращане на всички файлове в папка на Windows чрез отделни имейли

1. Първо, стартирайте програмата Outlook.
2. След това в Outlook отворете редактора на VBA във връзка със статията - „Как да стартирате VBA код във вашия Outlook".
3. След това копирайте и поставете следния VBA код в проект или модул.

Sub SendAllFilesInSeparateEmails()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFile As Object
    Dim strWindowsFolder As String
    Dim objFileSystem As Object
    Dim objMail As Outlook.MailItem
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       Set objWindowsFolder = objFileSystem.GetFolder(strWindowsFolder)
 
       'Send each file in an email
       For Each objFile In objWindowsFolder.Files
 
           'Create a new mail
           Set objMail = Outlook.Application.CreateItem(olMailItem)
           'Change the details as per your needs
           With objMail
                .Subject = Left(objFile.Name, Len(objFile.Name) - (Len(objFileSystem.GetExtensionName(objFile.Name)) + 1))
                .Attachments.Add objFile.Path
                .Recipients.Add ("someone@datanumen.com")
                .Recipients.ResolveAll
                .Send
          End With
       Next
 
       'Prompt you when completing sending
       MsgBox "All done!", vbOKOnly + vbExclamation
    End If
End Sub

4. След това можете да стартирате този макрос наведнъж. Просто натиснете бутона „F5”.
5. Впоследствие ще трябва да изберете изходната папка на Windows в изскачащия диалогов прозорец.
6. В крайна сметка Outlook ще прикачи всички файлове в тази папка на Windows, за да отдели имейлите и да ги изпрати до предварително дефинирания получател.
7. Когато приключи, ще получите съобщение, подканващо „Всичко готово!“.

Следете здравето на Outlook

Въпреки че Outlook е рекламиран като най-популярния имейл клиент на пазара, той все още има фатален недостатък. Това е неговата уязвимост. С други думи, Outlook е склонен към различни грешки и повреди. Ето защо трябва да обърнете голямо внимание на здравето на вашия Outlook, като го предпазите от повреди. Освен това, трябва да архивирате файловете си на Outlook редовно. Освен това се препоръчва да се сдобиете с инструмент за поправка на PST файлове, като например DataNumen Outlook Repair, То може ремонт на Outlook въпроси без никакви главоболия.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително sql корекция и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com