Как да групово експортирате множество имейли на Outlook в един документ на Word чрез VBA

Ако искате групово да експортирате множество имейли на Outlook в документ с една дума, можете да използвате VBA кода, показан в тази статия. Той може да ви помогне да изпълните тази задача в рамките на секунди.

Виждал съм как да конвертирам имейл на Outlook в документ на Word в предишната си статия - „2 ефективни метода за конвертиране на имейл на Outlook в документ на Word”. И двете средства, споменати в тази стрost ще бъде безпомощен в случая, когато искате да експортирате много имейли в един документ на Word. Следователно тук ще ви научим на друг начин. Сега прочетете, за да го получите подробно.

Групово експортиране на няколко имейла на Outlook в един документ на Word

1. Към starС, стартирайте вашата програма Outlook.
2. След това, след като влезете в главния прозорец на Outlook, трябва да натиснете бутоните на клавишите „Alt + F11“.
3. След това ще получите достъп до редактора на Outlook VBA, в който трябва да отворите празен модул.
4. След това копирайте VBA кода по-долу в отворения прозорец на модула.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. След това е по-добре да добавите този нов проект на VBA към лентата с инструменти за бърз достъп или лентата.
6. В крайна сметка можете да опитате.

• На първо място изберете няколко имейла на Outlook.
• След това намерете и кликнете върху новодобавения бутон на макрос.
• След като бъдете подканени да завършите, можете да прегледате предварително дефинираната локална папка, за да намерите нов документ на Word.
• Отворете този документ, в който можете да видите всички избрани имейли са експортирани.

Дръжте наблизо Могъщ инструмент за възстановяване

Независимо от многобройните функции, Outlook все още не може да бъде защитен от грешки. Ако сте свикнали да оставяте грешките сами, с натрупването им, сривът на Outlook определено ще се случи. В този момент е от съществено значение да се върнете към мощен и ефективен инструмент за възстановяване, като DataNumen Outlook Repair. Той е добре запознат с PST корекция. Докато е с него, няма да е необходимо да се притеснявате от загубата на данни за перспектива повече.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително повреден mdf и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com