Как бързо да експортирате статистика за гласуване от имейл на Outlook в работен лист на Excel

Ако сте изпратили имейл с бутони за гласуване, след като получателите ви изпратят своите отговори, може да искате да преброите и експортирате статистиката за гласуване в работен лист на Excel. И така, в тази стрost, ние ще ви научим как да го постигнете бързо.

Outlook е толкова мощен, че дори предлага функция „Гласуване“. Предишната ми статия "Умело използване на MS Outlook за гласуване” научи как да го използваме ефективно. Също така, most време, след гласуване, можете да продължите да експортирате статистиката за гласуване в работен лист на Excel по някои причини, като например желание да отпечатате статистиката. Но Outlook не поддържа това по подразбиране. Ето защо в следващите редове ще ви научим как да реализирате това като тапа.

Експортиране на статистика за гласуване в имейл към работен лист на Excel

1. В самото начало стартирайте приложението си Outlook.
2. След това трябва да натиснете клавишните бутони „Alt + F11“ в главния прозорец на Outlook.
3. След това в прозореца „Microsoft Visual Basic за приложения“ трябва да активирате „Microsoft Excel Object Library”. Щракнете върху „Инструменти“ > „Справка“. След това в изскачащия диалогов прозорец поставете отметка в квадратчето пред „Microsoft Excel Object Library” и накрая натиснете „OK”.
4. След това можете да поставите нов модул или да отворите такъв, който не се използва.
5. След това копирайте и поставете следните VBA кодове в този модул.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. След това, за удобен достъп, по-добре е да добавите новия макрос към лентата с инструменти за бърз достъп.
6. В крайна сметка можете да опитате.

• Първо изберете имейл източник, който съдържа бутони за гласуване.
• След това щракнете върху бутона за макрос в лентата с инструменти за бърз достъп.
• След като този макрос завърши изпълнението, можете да прегледате предварително дефинираната локална папка, в която ще видите нова работна книга на Excel.
• Отворете тази работна книга на Excel. Сега ще видите статистиката за гласуване, показана като изображението по-долу:

Никой не може напълно да предотврати грешките в Outlook

Въпреки че Outlook е надарен с различни възможности, няма такава функция, която да ни помогне да избегнем грешки в Outlook. Всякакви фактори могат да причинят грешки в Outlook. Например, ако често излизате от Outlook неправилно, вероятно ще страдате PST корупция. В такъв сценарий нямате друг избор, освен да използвате някои мощни инструменти, за да спасите вашия PST файл, като DataNumen Outlook Repair. Той спечели много похвали поради високия си процент на възстановяване.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително корумпиран mdf и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com