Как да изтриете групово всички разписки за четене във вашия Outlook

За да потвърдите, че получателите са прочели имейла ви, можете да поискате потвърждение за прочитане, когато го пишете. В тази ситуация пощенската ви кутия може да е пълна с такива потвърждения за прочитане. Тази публикация ще ви научи как да ги изтриете групово за постоянно.

След като прочетох статията „Как да изтриете групово всички разписки за доставка във вашия Outlook“, можете да помислите за подхода за групово изтриване на всички разписки за четене. Всъщност явната разлика между двата вида разписки е техният предмет. Разписката за доставка съдържа „Доставено“ в темата, но разписката за прочитане съдържа „Прочетено“ вместо това. Следователно можете да използвате същия начин за групово изтриване на всички разписки за четене. По-долу ще ви научим подробно на конкретните стъпки.

Групово изтриване на всички разписки за четене

1. В началото стартирайте Outlook.
2. След това отидете на Outlook VBA редактор чрез „Alt + F11“ според „Как да стартирате VBA код във вашия Outlook".
3. След това в новия прозорец отворете празен модул и поставете следния код в него.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. След това щракнете върху първата подпрограма.
5. Накрая натиснете бутона „F5”.
6. Веднага макросът ще работи, за да изтрие всички разписки за четене от вашия Outlook.
7. Когато приключи, ще получите подкана за резултата, като екранната снимка по-долу.
8. В момента можете да проверите вашите пощенски папки. Всички разписки за четене са изчезнали.

Защитете данните на Outlook

Въпреки че файлът на Outlook е податлив на повреда, ние можем да предприемем действия, за да го защитим. Например, трябва да поддържаме файла на Outlook в малък размер, да го защитаваме от злонамерени фактори и да го архивираме редовно. Не на последно място, по-добре е да подготвите мощен външен инструмент за поправка на PST, като например DataNumen Outlook Repair. Това ще окаже голямо влияние върху ремонта корумпиран Outlook файл.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително sql ремонт и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com