Как автоматично да зададете различно време за напомняне за срещи в Outlook в различни категории цветове

Ако класифицирате срещите на Outlook по цветови категории и искате да зададете различно време за напомняне за срещи в различни цветови категории, можете да се обърнете към тази статия. Тук ще ви научим да го реализирате с Outlook VBA.

Например, разделяте срещите на две групи. Едната е в цветова категория „Извън офиса“, тъй като мястото на срещата е твърде далеч, а другата е в цветова категория „На място“, тъй като мястото е точно тук. Сега искате Outlook да може автоматично да задава времето за напомняне за среща „извън офиса“ като 1 час преди началото и за среща „на място“ като 15 минути преди началото. Разглеждайки това изискване, по-долу ще споделим бърз метод.

Автоматично задаване на различно напомняне за срещи в различни цветови категории

1. Като начало стартирайте приложението си Outlook.
2. След това натиснете клавишите „Alt + F11“ за достъп до прозореца на VBA редактора.
3. След това, в следващия прозорец, копирайте и поставете VBA кода по -долу в проекта „ThisOutlookSession“.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. По-късно трябва да щракнете върху подпрограмата „Application_Startup“ и да натиснете клавиша „F5“, за да стартирате този макрос.
5. Оттогава всеки път, когато нова среща се добави към календара по подразбиране или промените съществуваща среща, Outlook автоматично ще проверява категориите на събранието и автоматично ще задава различното време за напомняне.

Премахване на грешки в Outlook

От време на време могат да възникнат различни проблеми с Outlook. Ето защо е изключително важно потребителите да се научат как да се справят с проблемите в Outlook. Като начало е по-добре да правите редовни резервни копия на данните на Outlook. Освен това, ако е възможно, се препоръчва да поддържате мощен Поправка на Outlook инструмент наблизо, като DataNumen Outlook Repair. Той може да сканира вашия PST файл, за да разбере проблемите с Outlook и след това да ги разреши с лекота.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително sql възстановяване и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com