Как автоматично да създадете ново назначение, когато имейл е маркиран в Outlook

Някои хора желаят автоматично или бързо да създадат нова среща в Outlook, когато маркират имейл. Тази статия ще представи подход за реализирането му с Outlook VBA.

Понякога може да получа имейл, в който се споменава среща или среща. Но това е просто имейл, вместо общ елемент на срещата в Outlook. В този случай трябва ръчно да създам нова среща в календара на Outlook. Това е малко обезпокоително. Така че ми се иска Outlook да може автоматично да създаде нова среща. Независимо от това, Outlook няма естествена поддръжка за нас, за да създадем автоматично нова среща автоматично, когато маркираме имейл. Следователно, за да го постигна, решавам да използвам Outlook VBA. Ето подробните кодове и стъпки на VBA.

Автоматично създаване на нова среща, когато имейл е маркиран

1. На първо място, преминете към раздела „Разработчик“ и натиснете бутона „Visual Basic“ в групата „Код“.
2. След това в новия прозорец „Microsoft Visual Basic for Applications“ трябва да щракнете двукратно върху „ThisOutlookSession“, за да отворите този проект.
3. И следващото копиране и поставяне на следните VBA кодове в него.

Public WithEvents olItems As Outlook.Items

Private Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub olItems_ItemChange(ByVal Item As Object)
    Dim oAppt As AppointmentItem
    Dim strMsg As String
    Dim nRes As Integer
 
    On Error Resume Next
 
    If TypeName(Item) = "MailItem" And Item.IsMarkedAsTask = True Then
       strMsg = "Do you want to create a new appointment"
       nRes = MsgBox(strMsg, vbYesNo + vbQuestion, "Confirm Creating Appointment")
       If nRes = vbYes Then
          Set oAppt = Application.CreateItem(olAppointmentItem)
          With oAppt
               .Subject = "New Appt: " & Item.Subject
               .Location = InputBox("Enter the Location, please.")
               'Type the concrete time, such as "12/29/2015 15:30"
               .Start = InputBox("Enter a specific time (format: MM/DD/YYYY hh:mm), please.")
               .Duration = 120
               .Body = "New Appointment: " & vbCrLf & vbCrLf & Item.Body
               .Attachments.Add Item
               .ReminderSet = True
               .ReminderMinutesBeforeStart = 30
               'Use ".Save" to directly save the new appointment
               .Display
          End With
       End If
 
      'To clear the flag on the email
      'If you want to keep email flagged, remove the following 4 lines
       With Item
            .ClearTaskFlag
            .Save
       End With
    End If
End Sub

4. Впоследствие трябва да използвате „Цифров сертификат за проекти на VBA“, за да създадете нов сертификат и да подпишете текущия проект „ThisOutlookSession“.
5. След това можете да излезете от прозореца „Visual Basic“ и да промените настройките на макроса, за да разрешите само макроси с цифрово подписване.
6. В крайна сметка можете да опитате.

• Първо, нанесете имейл и щракнете върху иконата „Flag“. Ще получите подкана, като следната екранна снимка:
• След като изберете „Да“, ще трябва да посочите местоположението и да натиснете бутона „OK“.
• След това трябва да посочите времето за среща.
• И накрая, след като щракнете върху „OK“, ще се отвори нова среща, показана като изображението по-долу:

Забележки:

1. В тези кодове на VBA напомнянето е зададено по подразбиране на 30 минути. Можете да го промените в кодовете по желание.
2. Кодовете определят продължителността на срещата на 120 минути, а именно 2 часа. Можете да промените реда ".Duration = 120" според вашите нужди.
3. Ако не сте посочили конкретно време, новата среща по подразбиране ще бъде зададена на текущата дата и час.
4. Можете да добавите реда „.Save“, за да запазите директно срещата.

Изхвърлете проблемите на Outlook

Известно е, че Outlook може да страда от различни проблеми. Най-лошата ситуация трябва да бъде корупцията на Outlook. Ако вашият файл на Outlook е повреден и имате резервно копие в ръка, можете лесно да възстановите своя повредени данни на Outlook от архиви. Но ако нямате резервно копие, ще трябва да поправите повредения файл на Outlook. В този случай можете да използвате вградения инструмент за ремонт, Scapst.exe, или да прибегнете до по-опитен инструмент, като DataNumen Outlook Repair.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително ремонт SQL Server mdf проблем с базата данни и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com