2 бързи начина за експортиране на списъка с всички маркирани имейли на Outlook в Excel

Ако искате да експортирате списъка с всички маркирани имейли от вашата пощенска кутия на Outlook в Excel, можете да използвате един от двата метода, споделени в тази статия.

Например, за да се справяте по-навреме с всички маркирани имейли или да ги споделяте с някой друг, може да се надявате да ги експортирате в работен лист на Excel. Тук ще представим 2 подхода за реализирането му. Първият използва стандартна функция „Импортиране и експортиране“ след намиране на маркирани имейли. За да бъда честен, това е малко досадно. По този начин във втория ще ви научим на по-удобен начин, който прилага VBA.

Метод 1: Експортирайте всички намерени маркирани имейли ръчно

1. На първо място, щракнете в полето за търсене над пощенския списък.
2. След това щракнете върху „Всички пощенски пратки“ в група „Обхват“ в раздела „Търсене“.
3. След това щракнете върху бутона „Сигнализиран“ в групата „Определяне“.
4. След всички маркирани имейли, показани в списъка, изберете една поща и натиснете „Ctrl + A“, за да изберете всички от тях.
5. След това натиснете клавишните комбинации „Ctrl + Shift + V“.
6. В новия диалогов прозорец създайте нова папка под файла на Outlook.
7. По-късно изберете новата създадена папка и щракнете върху „OK“, което ще премести всички намерени имейли с флаг в новата папка.
8. След това щракнете върху „Файл“> „Отваряне“> „Импортиране“,
9. В изскачащия диалогов прозорец изберете „Експортиране във файл“> „Напред“> „Microsoft Excel 97-2003“> „Напред“.
10. В новия екран изберете правилната папка и натиснете „Напред“.
11. След това следвайте съветниците, за да завършите „Експортиране“.
12. Ще получите нов файл на Excel, показан като следната екранна снимка.

Метод 2: Експортирайте списъка с всички маркирани имейли чрез VBA

1. В Outlook натиснете „Alt + F11“, за да задействате редактора на VBA.
2. След това активирайте „MS Excel Object“ в съответствие с „Как да добавите препратка към библиотека с обекти във VBA".
3. След това копирайте VBA кода по-долу в модул.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. И накрая, поставете курсора в подпрограмата „ExportAllFlaggedEmailsToExcel“ и натиснете бутона „F5“.
5. След това изберете файл на Outlook в новия диалогов прозорец.
6. Когато получите подкана „Завършено“, ще получите и нов файл на Excel, като изображението по-долу.

Защитете своя Outlook от корупция

Outlook е податлив на грешки и повреди, поради което за нас е много трудна задача да защитим данните си в Outlook. Несъмнено най-ефективният и практичен начин е да правим редовни резервни копия на данните за Outlook. В допълнение към това е необходимо да се сдобием с мощен и надежден инструмент за поправка на Outlook, като например DataNumen Outlook Repair. Ще стане полезно, ако инструмент за ремонт на входящата кутия не прави ефект.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително фиксира SQL Server и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com