2 метода за бързо изпращане на избрани клетки в работен лист на Excel като имейл на Outlook

Понякога може да искате бързо да вмъкнете избраните клетки в работен лист на Excel в имейл на Outlook и да изпратите този имейл. Тази статия ще разгледа това желание, за да ви предложи 2 метода.

Предишната ми статия „2 бързи метода за изпращане на работен лист на Excel като имейл в Outlook”Ви е научил как да изпращате цял работен лист на Excel като имейл. Понякога обаче искате само да изпратите избраните клетки в работен лист като имейл. В отговор на това изискване тук ще ви представим 2 метода. Можете да изберете или според вашите предпочитания.

Метод 1: Копирайте избраните клетки, за да изпратите ръчно имейл

1. За начало отворете изходния Excel файл и отворете правилния работен лист на Excel.
2. След това изберете клетките, които искате да изпратите като имейл на Outlook.
3. След това натиснете клавишните комбинации „Ctrl + C“, за да копирате избраните клетки.
4. След това стартирайте приложението си Outlook.
5. След това кликнете върху бутона „Нов имейл“ в лентата „Начало“, за да създадете нов имейл на Outlook.
6. По-късно в новия прозорец на съобщението щракнете върху раздела тяло на съобщението.
7. И след това натиснете бутоните „Ctrl + V“, за да поставите предварително копираните избрани клетки на Excel.
8. И накрая, можете да съставите имейла както обикновено и да кликнете върху бутона „Изпрати“, за да го изпратите.

Метод 2: Изпратете избрани клетки като имейл чрез VBA

1. В самото начало отворете работната книга на Excel.
2. След това натиснете бутоните „Alt + F11” за достъп до редактора на Excel VBA.
3. В новия прозорец щракнете върху „Вмъкване“> „Модул“, за да вмъкнете нов модул.
4. След това трябва да активирате обектите на Microsoft Outlook. Щракнете върху „Инструменти“ > „Препратки“. В изскачащия диалогов прозорец намерете и отметнете „Библиотека с обекти на Microsoft Outlook“.
5. След това копирайте следния VBA код в този модул.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. В крайна сметка можете да опитате.

• Първо, изберете конкретните клетки както обикновено.
• След това се върнете към новия макрос и натиснете клавиша F5, за да го активирате.
• Веднага ще се покаже нов имейл на Outlook, в който можете да видите, че избраните клетки са вмъкнати в тялото на имейла, като следната екранна снимка:

PST файлът е същият уязвим като файла на Excel

Както знаем, Excel файловете и Word документите са склонни към повреда. Всъщност, същото важи и за PST файла, който съдържа всички елементи във вашата пощенска кутия в Outlook. Така че е трудна задача да защитите PST данните си. Една от най-ефективните мерки е редовното архивиране на файла. Освен това, за да осигурите незабавно спасяване, е по-добре да си подготвите опитен инструмент, като например... DataNumen Outlook Repair, което е в състояние да възстановяване на Outlook данни без пот.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително ремонт mdf и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com