2 метода за групово изтриване на всички контакти без имейл адрес във вашия Outlook

Ако откриете, че някои контакти нямат имейл адрес във вашия Outlook, може да искате да обработите всяка папка с контакти, за да изтриете всички такива контакти. Тази публикация ще сподели с вас 2 начина.

Може би имате много контакти във вашия Outlook и някои от тях нямат имейл адрес. Ако смятате, че вече не са полезни, трябва да се надявате да изтриете всички контакти без имейл адрес. По стандартния начин можете да използвате „Незабавно търсене“, за да ги намерите и след това да ги изтриете ръчно, като следния метод 1. И все пак е малко досадно. Следователно в Метод 2 ще ви научим на друг по-ефективен начин.

Метод 1: Изтрийте ръчно след намиране на контакти без имейл адрес

1. За начало натиснете клавишите „Ctrl + 3“, за да получите достъп до панела „Контакти“.
2. След това щракнете в полето за търсене.
3. След това в появяващата се лента „Търсене“ кликнете върху „Всички елементи за контакт“.
4. След това кликнете върху „Има адрес“> „Има имейл адрес“.
5. След това в полето за търсене ще бъде добавен критерий „НЕ имейл адреси: = []“. Трябва да премахнете „НЕ“.
6. Впоследствие ще бъдат изброени всички контакти без имейл адрес.
7. Сега трябва ръчно да изберете контакти в резултатите от търсенето, така че и вашите групи контакти да са в списъка.
8. Накрая натиснете бутона „Del“, за да изтриете всички избрани контакти.

Метод 2: Групово изтриване на всички контакти без имейл адрес с VBA

1. Отначало натиснете „Alt + F11“, за да стартирате редактора на VBA в Outlook.
2. В новия екран копирайте следния VBA код в модул.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. По-късно щракнете върху подпрограмата „BatchDeleteAllContactsWithoutEmailAddress“.
4. В крайна сметка натиснете „F5“, за да задействате този макрос.
5. Когато завърши, ще получите съобщение за резултатите, като изображението по-долу.
6. Всички контакти без имейл адрес са преместени в папката „Изтрити елементи“.

Дръжте далеч от всички потенциални рискове

Outlook може да се повреди поради различни фактори, като вируси, потребителски грешки, софтуерни грешки, както и хардуерни грешки. Трябва да сте склонни да изпитвате щети в Outlook, така че трябва да държите всички тези потенциални рискове на разстояние. Например, трябва да монтирате мощен антивирусен софтуер на вашия компютър. Освен това трябва редовно да архивирате данните си в Outlook. Не на последно място, по-добре подгответе здрав и надежден инструмент за ремонт, като например DataNumen Outlook Repair. Той може да поправи вашия корумпиран PST файл с лекота.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително SQL Server корупция и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com