2 бързи начина за извличане на раздели от вашия Word документ

В тази статия ще ви предложим 2 бързи и лесни начина за извличане на раздели от вашия документ на Word в друг или няколко.

Доста често се случва извличане на съдържание от един документ в друг. И в предишната ни статия обсъдихме как да извлечем страници от документа. За подробна информация можете да се обърнете към тази статия: 2 бързи начина за извличане на отделни страници от вашия Word документ

Днес ще ви покажем как да извличате по раздели.    

Метод 1: Извличане на текущия раздел в нов документ

1. Първо, позиционирайте курсора в целевата секция.
2. След това натиснете „Alt + F11“, за да извикате редактора на VBA в Word.
3. След това в лявата колона кликнете върху „Нормално“.
4. И в лентата с менюта щракнете върху „Вмъкване“.
5. След това изберете „Модул“ от това падащо меню.
6. Щракнете двукратно, за да отворите новия модул и поставете там следните кодове:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. След това кликнете върху „Run“ в лентата с менюта или натиснете „F5“.
8. След това ще се появи прозорецът „Преглед“. Изберете място за съхранение на новия документ и щракнете върху „OK“.
9. И в полето „Име на файла“ въведете името на новия файл и щракнете върху „OK“.

Сега сте извлекли раздела в нов документ.

Метод 2: Извличане на всеки раздел в документа на отделни нови

Този начин може да ви помогне да обработите групово всички раздели в документ. Разбира се, ще ни трябва и макрос.

1. За начало отворете целевия документ.
2. След това следвайте стъпките в метод 1, за да инсталирате и стартирате макрос.
3. Само този път заменете този макрос с този:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. И все пак, в прозореца „Преглед“ изберете път за съхранение и щракнете върху „OK“.

Коригирайте дразнещи грешки в думите

Често се срещат грешки в Word, докато се използва. Досадно може да е, трябва да отделим време да го направим възстановяване на дума възможно най-скоро. Тъй като колкото по-дълго го забавяме, толкова по-тежка може да бъде загубата на данни. Затова се препоръчва да се сдобиете с ремонтна програма предварително.

Въведение на автора:

Вера Чен е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително повреден xls и pdf ремонт на софтуерни продукти. За повече информация посетете WWW.datanumen.com