如何快速将 Outlook 电子邮件导出为图像文件

有些用户希望将 Outlook 电子邮件导出为图像文件，例如 jpg 文件。 因此，在本文中，我们将向您介绍如何通过 Outlook VBA 代码获取它。

您一定已经学会了将电子邮件导出为文本文件、Word 文档等的各种技巧。 那么，如何将电子邮件导出为 JPG 文件之类的图片呢？ 显然，Outlook 没有这个功能。 但是，在下文中，我们将与您分享一个快速的方法。

快速将 Outlook 电子邮件导出为图像文件

1. 对于作为tart，启动您的 Outlook 应用程序。
2. 然后，在 Outlook 主窗口中，根据文章访问 VBA 编辑器 – “如何在 Outlook 中运行 VBA 代码“。
3. 接下来，启用“MS Word 对象库rary”和“多发性硬化症 PowerPoint 对象库rary” 通过引用文章 – “如何添加对象库rary VBA 中的引用“。
4. 接下来，将以下 VBA 代码复制并粘贴到空白模块中。

Sub ExportEmailAsImage()
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim strWordDocument As String
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objDocumentRange As Word.Range
    Dim objPowerPointApp As PowerPoint.Application
    Dim objPresentation As PowerPoint.Presentation
    Dim objShape As PowerPoint.Shape
 
    On Error Resume Next
    'Export the email as Word document
    Set objMail = Outlook.Application.ActiveExplorer.Selection(1)
    strFileName = Replace(objMail.Subject, "/", " ")
    strFileName = Replace(strFileName, "\", " ")
    strFileName = Replace(strFileName, ":", "")
    strFileName = Replace(strFileName, "?", " ")
    strFileName = Replace(strFileName, Chr(34), " ")
    strWordDocument = Environ("Temp") & "\" & strFileName & ".doc"
 
    objMail.SaveAs strWordDocument, olDoc

    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Open(strWordDocument)
    objWordApp.Visible = True
 
    objWordApp.Selection.Find.ClearFormatting
    objWordApp.Selection.Find.Replacement.ClearFormatting
 
    With objWordApp.Selection.Find
        .Text = "^p^p"
        .Replacement.Text = "^p"
        .Wrap = wdFindContinue
    End With
 
    'Insert the document into a PowerPoint Presentation slide as an object
    objWordApp.Selection.Find.Execute Replace:=wdReplaceAll
    Set objDocumentRange = objWordDocument.Range()
    objDocumentRange.Font.Name = "Calibri"
    objDocumentRange.Font.Size = 10
    objWordDocument.Close True
    objWordApp.Quit
 
    Set objPowerPointApp = CreateObject("PowerPoint.Application")
    Set objPresentation = objPowerPointApp.Presentations.Add
    objPowerPointApp.Visible = msoTrue
 
    With objPresentation
        .PageSetup.SlideHeight = 792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
 
    'Export the slide
    With objPresentation.Slides(1)
         Set objShape = .Shapes.AddOLEObject(0, 0, 612, 792, , strWordDocument)
        .Export "E:\Email_" & strFileName & ".jpg", "JPG"
    End With
 
    objPresentation.Saved = msoTrue
    objPresentation.Close
    objPowerPointApp.Quit
End Sub

5. 之后，您需要将宏添加到快速访问工具栏。
6. 随后，您可以关闭 VBA 编辑器。
7. 稍后，选择一封电子邮件并点击快速访问工具栏中的宏按钮。
8. 宏完成后，您可以转到预定义的本地文件夹以查找从此电子邮件导出的图像文件。

从损坏的文件中检索 Outlook 数据

如果您的 Outlook 文件受到严重损坏，您可能会非常沮丧。 在这种情况下，您将继续从受损文件中提取 Outlook 数据。 一些用户会倾向于使用收件箱修复工具。 然而，米ost 时间，它不会产生效果。 因此，你最好保持一个强大可靠的 PST修复 工具，例如 DataNumen Outlook Repair. 它可以扫描损坏的文件并毫不费力地取回最大数据。

作者简介：

Shirley Zhang 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括 中密度纤维板修复 和 outlook 修复软件产品。 欲了解更多信息，请访问 datanumen.com