如何通过 VBA 将文件夹结构从一个 Outlook PST 文件快速复制到另一个

如果你想将文件夹结构从一个Outlook PST文件复制到另一个，你可以使用本文介绍的方法，它会教你如何使用VBA一次性搞定。

也许，为了更好地管理您的电子邮件，您已经在主 Outlook 文件中创建了几个自定义文件夹。 因此，在创建新的 Outlook PST 文件时，您可能希望应用相同的文件夹结构。 实际上，在我之前的文章中——“只需两步即可在新 Outlook 文件中保留当前文件夹层次结构”，你可以学习一种传统的方法，即使用“存档”功能来实现它。 尽管如此，实际上，它还是有点乏味。 与之相比，使用VBA代码获取会快很多。 因此，在下文中，我们将详细的步骤和代码告诉您。

将文件夹结构从一个 Outlook PST 文件复制到另一个

1. 首先，启动 Outlook 程序。
2. 然后在 Outlook 窗口中，按“Alt + F11”键按钮。
3. 接下来您将进入 Outlook VBA 编辑器窗口。
4. 随后，将以下 VBA 代码复制并粘贴到新模块中。

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

5. 之后，将您的宏安全级别更改为低。
6. 稍后返回 VBA 编辑器窗口并按“F5”键按钮运行宏。
7. 最后，宏完成工作后，您会收到一条消息，提示“已完成！”。
8. 此时，您可以转到邮件导航窗格。 您将看到一个新的 Outlook 数据文件，它与源 PST 文件位于相同的文件夹结构中，如下图所示：

应对令人沮丧的 PST 问题

由于 Outlook PST 容易出错，所以你们中的许多人一定在 Outlook 中遇到过各种问题。 面对它们，您可以先使用Outlook收件箱修复工具试一试。 如果失败，您可以应用更强大的第三方工具，例如 DataNumen Outlook Repair，这可以 修复Outlook PST 错误轻而易举。

作者简介：

Shirley Zhang 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括 SQL Server 固定 和 outlook 修复软件产品。 欲了解更多信息，请访问 datanumen.com