如何快速附加特定幻灯片 PowerPoint 演示到您的 Outlook 电子邮件

如果你想提取一个特定的幻灯片 PowerPoint 演示文稿到一个单独的新演示文稿并将其附加到 Outlook 电子邮件中，您可以使用本文中分享的方式。

而不是附加整个 PowerPoint 演示文稿到电子邮件，如果要附加演示文稿的特定幻灯片，一般情况下，您需要先将特定幻灯片复制到新的演示文稿中。 太麻烦了。 因此，在这里我们将向您展示一种可以一次性实现的方法。

附上特定幻灯片 PowerPoint 电子邮件演示

1. 首先打开具体的 PowerPoint 演示。
2. 那么，在 PowerPoint 应用程序窗口，按“Alt + F11”键访问 VBA 编辑器。
3. 接下来，在新窗口中，点击“插入”>“模块”创建一个新模块。
4. 随后，将以下 VBA 代码复制并粘贴到该模块中。

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. 之后，您可以关闭当前窗口。
6. 稍后，转到“文件”>“选项”>“快速访问工具栏”将新宏添加到快速访问工具栏。
7. 最后，你可以试试这个宏。

• 对于作为tart，选择要提取的特定幻灯片。
• 然后，单击快速访问工具栏中的宏按钮。
• 马上会出现一封 Outlook 邮件，里面有一个 PowerPoint 从源演示文稿中提取的演示文稿。

使用有效的恢复工具

众所周知，Outlook 内置了一个修复工具—— 扫描仪. 然而，它可以简单地应对 Outlook 中的小故障。 如果你面对的是严重的伤害，它不会产生效果。 到那时，您别无选择，只能重新使用另一个功能强大且值得信赖的修复工具，例如 DataNumen Outlook Repair. 有了它，您将能够挽救损坏的 Outlook 文件。

作者简介：

Shirley Zhang 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括 损坏的中密度纤维板 和 outlook 修复软件产品。 欲了解更多信息，请访问 datanumen.com