如何快速将 Word 文档的特定页面附加到 Outlook 电子邮件

MS Word 有一个直接功能，支持用户将当前的 Word 文档作为电子邮件附件发送。 但有时，您可能只希望将 Word 文档的特定页面附加到 Outlook 电子邮件中。 现在，这篇文章就给大家分享一个方法。

要在 MS Word 应用程序中将整个 Word 文档作为电子邮件附件发送，您只需转到“文件”菜单并转到“保存并发送”选项卡，在该选项卡下您可以找到“作为附件发送”按钮。 然而，有时您想要发送的可能只是文档的特定页面。 这种情况下，可以使用下面介绍的方法来完成。

将 Word 文档的特定页面附加到电子邮件

1. 首先，您应该打开要通过电子邮件发送其特定页面的源 Word 文档。
2. 然后，进入 MS Word 窗口后，您需要按“Alt + F11”键按钮。
3. 接下来，您将可以访问 MS Word 中的 VBA 编辑器。
4. 之后，您必须启用“Microsoft Outlook Object Library”。 您可以点击“工具”>“参考”来实现它。
5. 随后，您应该将以下 VBA 代码复制到未使用的模块中。

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. 最后，您可以运行此宏。 只需按 F5 键按钮或点击工具栏中的“运行”图标。
7. 宏完成后，将显示一封新的 Outlook 电子邮件，其中附有源 Word 文档的摘录，如下图所示：

从损坏的 Outlook 文件中提取最大数据

如果您使用 Outlook 数十年，您可能遇到过各种 Outlook 问题，包括弹出内部错误消息、突然崩溃以及严重的文件损坏。 由于事实上 扫描仪，内置修复工具，只能处理小问题，你最好随身携带一个强大的外部修复工具，比如 DataNumen Outlook Repair. 它能够从损坏的 Outlook 数据文件中提取最大数据。

作者简介：

Shirley Zhang 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括 修复 和 outlook 修复软件产品。 欲了解更多信息，请访问 datanumen.com