如何从具有特定职务的所有 Outlook 联系人快速创建联系人组

为了更轻松地与具有特定职位的联系人进行交流，您可能希望从这些联系人中快速创建一个联系人组。 现在，在本文中，我们将与您分享一种快速方法。

如果您经常向具有特定职位的联系人批量发送电子邮件、任务或会议邀请，那么将他们创建一个联系人组会方便得多。 通常，按照标准方式，您需要先创建一个新的联系人组，然后将联系人逐个添加到组中作为成员。 有点麻烦。 因此，接下来，我们将教大家一个更快捷的获取方式。

从具有特定职位的所有联系人创建联系人组

1. 首先，在“联系人”文件夹中，选择一个具有特定职位的联系人。
2. 然后，按“Alt + F11”访问 Outlook VBA 编辑器。
3. 接下来，将以下 VBA 代码复制到空白模块或项目中。

Dim objContact As Outlook.ContactItem
Dim strJobTitle As String
Dim objNewGroup As Outlook.DistListItem
Dim objTempMail As Outlook.MailItem

Sub CreateContactGroupfromContactsSameJobTitle()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objContact = Outlook.Application.ActiveExplorer.Selection(1)
    strJobTitle = objContact.JobTitle
 
    Set objNewGroup = Outlook.Application.CreateItem(olDistributionListItem)
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
 
    'Process all Contacts folders
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
 
    objNewGroup.AddMembers objTempMail.Recipients
    objNewGroup.Display
End Sub

Sub ProcessContactsFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If objItem.Class = olContact Then
           If objItem.JobTitle = strJobTitle Then
              'Add the contact having the specific job title to the new group
              objTempMail.Recipients.Add (objItem.Email1Address)
              objTempMail.Recipients.ResolveAll
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

4. 之后，将光标移动到第一个子程序。
5. 最后，点击“F5”键按钮运行这个宏。
6. 宏完成后，将显示一个新的联系人组。 它包含与步骤 1 中所选联系人具有相同职务的所有联系人。

有效屏蔽Outlook数据

Outlook虽然功能丰富，但也摆脱不了易受攻击的事实。 所以，如果您不想丢失宝贵的 Outlook 数据，就必须努力保护它。 例如，您需要定期备份 Outlook 数据。 另外，如果负担得起，建议拥有尖端的 PST 修复工具，例如 DataNumen Outlook Repair，这可以 修复PST jiff 中的数据。

作者简介：

Shirley Zhang 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括 损坏的sql 和 outlook 修复软件产品。 欲了解更多信息，请访问 datanumen.com